SAS中四个表的每个单元的平均值

Question

我有三个表，如下所示：

     A   B   C             A   B   C              A    B    C     
D    1   2   3        D    2   3   4         D    3    4    5
E    4   5   6        E    5   6   7         E    6    7    8 
F    7   8   9        F    8   9   10        F    9    10   11

我想在SAS中逐个单元查找这些表的平均值。 因此输出应如下所示：

     A   B   c
D    2   3   4
E    5   6   7 
F    8   9   10

因此，第一个像元的计算方式如下（1 + 2 + 3）/ 3 = 3

目前，我对如何执行此操作完全感到困惑，但是我正在研究proc手段和proc freq，它们似乎很有希望。

预先感谢您的帮助。

Answer 1

在SAS / IML中，这很简单。

proc iml;
  a = {1 2 3,4 5 6,7 8 9};
  b = {2 3 4,5 6 7,8 9 10};
  c = {3 4 5,6 7 8,9 10 11};
  d = (a+b+c)/3;
 print a b c d;
quit;

在SQL或基本SAS中，还有多种方法可以解决此问题，并且假设您键入了第三个数据集（DFG应该为DEF）。 如果您没有输入错误，那将变得更加困难。

data a;
input ID $ a b c;
datalines;
D    1   2   3 
E    4   5   6 
F    7   8   9 
;;;;
run;

data b;
input ID $ a b c;
datalines;
D    2   3   4   
E    5   6   7   
F    8   9   10  
;;;
run;

data c;
input ID $ a b c;
datalines;
D    3    4    5
E    6    7    8 
F    9    10   11
;;;;
run;

data for_d;
  set a b c;
  by id;
run;

proc means data=for_d;
  var a b c;
  class ID;
  output out=d mean=;
run;

SQL解决方案的类型更多，但最终还是类似的（您可以跳过for_d步骤）。 只需将a，b，c连接在一起并计算查询中的均值。