SAS保留声明

Question

假设我有一个包含三个变量的数据集：
身份证年份状态
1 2017年
1 2017 N
1 2018 N
1 2018年
2 2017年
2 2017
2 2018 N
2 2018 N

我想创建一个名为NEW的第四列，它具有三个可能的值（“ Yonly”，“ Nonly”和“ yesno”）。 在上面的示例中，输出为：
身份证年份状态新
1 2017年
1 2017 N是
1 2018 N
1 2018年是否
2 2017年
2 2017年
2 2018 N
2 2018年

注意：可能缺少数据。 到目前为止，我的解决方案是错误的：

retain tmp '';
by ID Year;
if Status='Y' then tmp='Yonly';
if Status='N' then tmp='Nonly';
if tmp='Yonly' and Status='N' then tmp='yesno';
  if tmp='Nonly' and Status='Y' then tmp='yesno';
if last.Year=1 then NEW=tmp;

请帮忙？ 任何方法都可以，您不必使用RETAIN。

Answer 1

这是按照您正在执行的操作进行的，但是最好像这样执行条件操作。

data want;
  set have;
  by id year;
  retain last_status;
  if first.year then last_status = status;
  if last.year then do;
    if status = last_status or missing(last_status) then new=cats(status,'only');
    else if missing(status) then new=cats(last_status,'only');
    else new='yesno';
  end;
run;

retain第一行中的值，然后retain最后一行中的内容，只需根据这两个变量考虑要做什么-这样很简单。

Answer 2

确保定义TMP的长度。 您的当前代码会将TMP的长度设置为1，因为首次使用是RETAIN语句中列出的初始值。

您在启动新组时缺少初始化步骤。

if first.year then tmp=' ';

您的方法只能在每个组的最后一条记录上设置结果。 如果您希望组中的所有观测值都具有相同的值，那么我建议使用双DOW循环。 第一个循环可用于查看是否存在“ Y”或“ N”状态。 然后，您可以计算您的NEW变量。 然后，第二个循环将再次读取该组的数据，并将值写出。 因为对一个组的所有观察都是在单个数据步骤迭代中处理的，所以无需使用RETAIN。

data want ;
  do until (last.year) ;
    set have ;
    by id year ;
    y = y or (status='Y');
    n = n or (status='N');
  end;
  length new $8;
  if Y and N then new='yesno';
  else if Y then new='yesonly';
  else if N then new='noonly';
  else new='none';
  drop y n ;
  do until (last.year) ;
    set have ;
    by id year ;
    output ;
  end;
run;