SPARQL-返回主题列表的共同对象

Question

我如何获取所有主题共享的谓词和对象-却不了解这些主题的谓词/对象？
让我们看一下来自Wikidata的示例查询：

SELECT ?chancellor WHERE{
    ?chancellor wdt:P39 wd:Q4970706. #P39 = position held, Q4970706 = Chancellor of Germany
}

链接到该查询。

该查询返回所有德国前总理。
现在我想返回每个总理共同拥有的每个谓词和宾语，例如，每个主语都是人类的一个实例，出生于德国或其他任何地方。
我想这很容易。 但是我不知道。

Answer 1

这个不错。 这是热门影片：

prefix wdt: <http://www.wikidata.org/prop/direct/>
prefix wd: <http://www.wikidata.org/entity/>

select ?p ?o (count(distinct ?chancellor) as ?cs) where {
    ?chancellor wdt:P39 wd:Q4970706.  
    ?chancellor ?p ?o .
}
group by ?p ?o
order by desc(?cs)

链接查询

这需要所有总理及其属性和价值。 它计算每个道具/ val的校长人数。

通过订购，您可以在顶部看到最常见的道具/价格。

现在，您想要的只是所有总理的结果。 我们可以很容易地获得一个查询中的总理大臣人数，并将两者结合在一起：

prefix wdt: <http://www.wikidata.org/prop/direct/>
prefix wd: <http://www.wikidata.org/entity/>

select ?p ?o where {
   {
       # Find number of chancellors 
       select (count(?chancellor) as ?num_chancellors) where { 
           ?chancellor wdt:P39 wd:Q4970706
       }
   }
   {
       # Find number of chancellors per predicate / value
       select ?p ?o (count(distinct ?chancellor) as ?chancellor_count) where {
           ?chancellor wdt:P39 wd:Q4970706.  
           ?chancellor ?p ?o .
       }
       group by ?p ?o 
   }
   # Choose results all chancellors share 
   filter (?num_chancellors = ?chancellor_count)
}

链接到查询 。

我认为这可以满足您的需求。 我承认，不是很漂亮。

Answer 2

SPARQL和RDF一个有趣的方面是，您无需了解有关数据的任何信息即可查询它。 在您的情况下，我建议添加三元模式?chancellor ?p ?o . 并选择?p和?o 。 在这里，您可以选择要查找的任何属性。 如果某些?chancellor匹配不具有该属性值，请确保使用OPTIONAL 。