Word宏VBA查找特定的样式/列表并将其转换为文本

Question

我正在尝试使用Word宏选择样式为“ Number_List”的所有文本，然后在其上调用.ConvertNumbersToText函数。 我在仅找到列表或特定样式时遇到麻烦。

Dim selBkUp As Range
Set selBkUp = ActiveDocument.Range(ActiveDocument.Range.Start, ActiveDocument.Range.End)
With ActiveDocument.Range.Find
    .Style = ActiveDocument.Styles("Number_List")
    .Forward = True
    .Wrap = wdFindContinue
    Dim SearchSuccessful As Boolean
    SearchSuccessful = .Execute

    If SearchSuccessful Then
        selBkUp.Select
        Selection.Range.ListFormat.ConvertNumbersToText
    Else
        ' code
    End If
End With

我选择了整个文档，然后将所有列表中的数字都转换为文本，但是我尝试仅选择具有该特定样式的样式，或者避免使用其他5种可能出现或可能不出现的样式。 任何帮助，将不胜感激！

Answer 1

以下代码将搜索一种样式，如果找到，将转换为另一种样式。 该代码下面是另一个子例程，该子例程将列出文档中找到的所有样式。

' From http://forums.codeguru.com/showthread.php?448185-Macro-to-Change-Styles-in-Word
' This code will search for a specified Style and convert that to another Style
Sub FindReplaceStyle()
    Selection.HomeKey wdStory
    Selection.Find.ClearFormatting
    Selection.Find.Replacement.ClearFormatting

    With Selection.Find
         .Style = "Normal"                      ' Look for 'Normal'
         '.Text = ""
         .Replacement.Style = "Heading 1"       ' Change to 'Heading 1'
    '     .Replacement.Text = ""
         .Forward = True
         .Wrap = wdFindStop
         .Format = True
         .MatchCase = False
         .MatchWholeWord = False
         .MatchWildcards = False
         .MatchSoundsLike = False
         .MatchAllWordForms = False
    End With

    Do While Selection.Find.Execute()
        If Selection.Start = Selection.Paragraphs.First.Range.Start Then
            Selection.Style = "Heading 1"
        End If

        Selection.Collapse wdCollapseEnd
    Loop

End Sub

下面的代码将生成在文档中找到的所有样式的列表。

另外，尝试使用您的“ Number_List”时出现错误

' Following code from: http://www.vbaexpress.com/forum/showthread.php?41125-How-to-get-all-the-applied-Paragraph-Styles-of-a-document
 Sub GetActiveStyles()
    Application.ScreenUpdating = False
    Dim RngStory As Range, oSty As Style, StrType As String, StrStyles As String
    With ActiveDocument
        For Each oSty In .Styles
            For Each RngStory In .StoryRanges
                With RngStory.Find
                    .ClearFormatting
                    .Text = ""
                    .Replacement.Text = ""
                    .Style = oSty.NameLocal
                    .Forward = True
                    .Wrap = wdFindStop
                    .Format = True
                    .Execute
                    If .Found Then
                        Select Case oSty.Type
                        Case wdStyleTypeCharacter: StrType = "Character"
                        Case wdStyleTypeList: StrType = "list"
                        Case wdStyleTypeParagraph: StrType = "Paragraph"
                        Case wdStyleTypeTable: StrType = "Table"
                        End Select
                        StrStyles = StrStyles & oSty.NameLocal & " (" & StrType & ")" & vbCr
                        Exit For
                    End If
                End With
            Next RngStory
        Next oSty
    End With
    Debug.Print StrStyles
    'MsgBox StrStyles
    Application.ScreenUpdating = True
End Sub