VBA：函数给出“运行时错误'424'：所需对象”调用时错误

Question

我有两个主要功能，第一个是search_bank。 它按单元格搜索``贷方''，``类型''和``存储''列，并找出是否存在匹配项;如果存在匹配项，则返回True，并且副作用会更改匹配单元格的颜色。

我正在用来测试第一个功能的第二个子 。 我遇到的问题是，我收到运行时错误“ 424”：所需的对象 ，没有表明问题出在哪里。

这是第一个功能：

Function search_bank(Store As String, amount As Double, Amex As Boolean) As Boolean
    Dim m_store As Range
    Dim m_type As Range
    Dim Credit_Amt_Col As Range

    Set m_store = bank_sheet.Range("1:1").Find("M_STORE")
    Set m_type = bank_sheet.Range("1:1").Find("M_TYPE")
    Set Credit_Amt_Col = bank_sheet.Range("1:1").Find("Credit Amt")

    search_bank = False
    Dim i As Long
    For i = 1 To 9000
        If Not search_bank Then
            Dim store_cell As Range
            Dim type_cell As Range
            Dim credit_cell As Range

            Set store_cell = Worksheets(2).Cells(i, m_store.Column)
            Set type_cell = Worksheets(2).Cells(i, m_type.Column)
            Set credit_cell = Worksheets(2).Cells(i, Credit_Amt_Col.Column)

            If InStr(UCase(store_cell.Value), UCase(Store)) > 0 And credit_cell.Value = amount Then
                If store_cell.Interior.ColorIndex <> 46 Then
                    If Amex And InStr(UCase(type_cell.Value), UCase("amex deposit")) Then
                        store_cell.Interior.ColorIndex = 46
                        search_bank = True

                    End If
                    If Not Amex And InStr(UCase(type_cell.Value), UCase("Credit Card Deposit")) Then
                        store_cell.Interior.ColorIndex = 46
                        search_bank = True

                    End If
                End If
            End If
        End If
    Next i

End Function

这是测试人员：

Sub Tester()
    Dim x As Boolean
    x = search_bank("ctc", 38.4, True)
    Debug.Print (x)
End Sub

我尝试在测试仪上使用“设置”：

Sub Tester()
    Dim x As Boolean
    Set x = search_bank("ctc", 38.4, True)
    Debug.Print (x)
End Sub

甚至在通过测试器之前声明变量（我不太习惯VBA，但有一段时间我相信它是如此古老，需要在传递它们之前声明一些东西）

Sub Tester()
    Dim x As Boolean
    Dim store As String
    Dim Amount As Double
    Dim amex As Boolean
    store = "ctc"
    Amount = 38.4
    amex = True
    x = search_bank(store, Amount, amex)
    Debug.Print (x)
End Sub

Answer 1

如果可以的话，我会将其发布为评论，但我不能。 因此，我知道这不会直接解决问题，但会有助于调试。 见下文：

Function search_bank(Store As String, amount As Double, Amex As Boolean) As Boolean
Dim m_store As Range
Dim m_type As Range
Dim Credit_Amt_Col As Range

' It is always best to check the inverse of an object before setting
' setting an object variable to the target object. In this case
' I check to make sure each range can be found, and if not, I
' debug.print which variable cannot be set.

Set m_store = bank_sheet.Range("1:1").Find("M_STORE")
Set m_type = bank_sheet.Range("1:1").Find("M_TYPE")
Set Credit_Amt_Col = bank_sheet.Range("1:1").Find("Credit Amt")

If m_store is Nothing then Debug.Print "m_store is nothing"
If m_type is Nothing then Debug.Print "m_type is nothing"
If Credit_Amt_Col is Nothing then Debug.Print "Credit_Amt_Col is nothing."

search_bank = False
Dim i As Long
For i = 1 To 9000
    If Not search_bank Then
        Dim store_cell As Range
        Dim type_cell As Range
        Dim credit_cell As Range

        ' Use the inverse method above on these three items as well.
        Set store_cell = Worksheets(2).Cells(i, m_store.Column)
        Set type_cell = Worksheets(2).Cells(i, m_type.Column)
        Set credit_cell = Worksheets(2).Cells(i, Credit_Amt_Col.Column)

        If InStr(UCase(store_cell.Value), UCase(Store)) > 0 And credit_cell.Value = amount Then
            If store_cell.Interior.ColorIndex <> 46 Then
                If Amex And InStr(UCase(type_cell.Value), UCase("amex deposit")) Then
                    store_cell.Interior.ColorIndex = 46
                    search_bank = True

                End If
                If Not Amex And InStr(UCase(type_cell.Value), UCase("Credit Card Deposit")) Then
                    store_cell.Interior.ColorIndex = 46
                    search_bank = True

                End If
            End If
        End If
    End If
Next i

End Function

我在网上发表了评论，但基本上我为前三个对象添加了一个反向检查（您也想对第二组对象执行此检查）。 这是最佳做法，但在这种情况下，它也（希望）可以帮助您查明找不到对象的位置。

Answer 2

您的OP下有很多不错的评论，@ BrandonBarney的回答也不错，但这是我的两分钱：

占一：我看到的最大的事情是，您永远不会声明blank_sheet ，而是在设置范围对象时尝试使用它。 这是您的错误出处。 它正在寻找做Range("1:1").Find("M_STORE") ，但不知道bank_sheet是什么。

要点二：向您指出的一种快速方法是， 始终在代码顶部使用Option Explicit 。 这样可以确保显式声明您使用的任何变量。 即：

Option Explicit

Function search_bank(Store As String, amount As Double, Amex As Boolean) As Boolean
    Dim m_store As Range
    Dim m_type As Range
    Dim Credit_Amt_Col As Range

    ''''' New code here: ''''''
    Dim bank_sheet as Worksheet
    Set bank_sheet = Worksheets("Bank Sheet") ' change to whatever the name is.
    '''''''''''''''''''''''''''
    Set m_store = bank_sheet.Range("1:1").Find("M_STORE")
    Set m_type = bank_sheet.Range("1:1").Find("M_TYPE")
    Set Credit_Amt_Col = bank_sheet.Range("1:1").Find("Credit Amt")
    ' etc. etc.

如果您偶然输入错字， Option Explicit也将提供帮助。 因此，如果您曾经使用bank_sheeet.Range("A:A")它将出错并要求您声明bank_sheeet 。 或者，当然，您会意识到这是一个错字，然后对其进行修复。

奖励分：您可以结合使用Dim来节省几行：
Dim m_store as Range, m_type as Range, Credit_Amt_Col as Range可以全部在一行上。

（注意：将Dim m_store, m_type, Credit_Amt_Col as Range设置Dim m_store, m_type, Credit_Amt_Col as Range 不会将所有三个设置为Range类型。由于未声明m_store和m_type因此会使m_store和m_type成为Variant 。在这种情况下，只有Credit_Amt_Col将是Range 。因此，您仍然必须明确说明每个变量的类型）。