如果功能给我带来问题

Question

我的值一直是假的，而不是即使我输入Male时也添加的值。 有人有什么主意吗？

If gender = "Male" Then
Sheet2.Range("A2").Value = "he" & Sheet2.Range("A3").Value = "him" & Sheet2.Range("A4").Value = "his"
Else
Sheet2.Range("A2").Value = "she" & Sheet2.Range("A3").Value = "her" & Sheet2.Range("A4").Value = "her"
End If

Answer 1

您不能在同一条语句中两次分配值。 第一个字符之后的任何=字符被视为逻辑运算符（等于），而不是分配。

因此，如果您有：

a = b = c

VBA将该语句视为：将“是否b等于c”的结果分配给A。 如果语句中有三个等号，它将变得更加复杂，但是无论如何它都不是您想要的。

另外，＆运算符用于字符串连接。 所以

a = "top" & "hat"

将字符串“ tophat”分配给a。

您可能要使用：运算符而不是＆。 这将语句分隔在一行上。 所以试试这个：

If gender = "Male" Then
Sheet2.Range("A2").Value = "he" : Sheet2.Range("A3").Value = "him" : Sheet2.Range("A4").Value = "his"
Else
Sheet2.Range("A2").Value = "she" : Sheet2.Range("A3").Value = "her" : Sheet2.Range("A4").Value = "her"
End If

但是，我敦促您不要在这里使用：。 确实没有必要，我认为这使代码更难阅读。 我建议：

If gender = "Male" Then
    Sheet2.Range("A2").Value = "he"  
    Sheet2.Range("A3").Value = "him"
    Sheet2.Range("A4").Value = "his"
Else
    Sheet2.Range("A2").Value = "she"
    Sheet2.Range("A3").Value = "her"  
    Sheet2.Range("A4").Value = "her"
End If

Answer 2

Rich Holton告诉您代码无法正常工作的原因

在这里，我向您提出一些不同的技巧

Option Explicit

Sub main()
    Dim valsArray As Variant '<--| declare a Variant variable to hold an array
    Dim gender As String

    gender = "Male" '<--| gender initialization for testing purposes

    If gender = "Male" Then
        valsArray = Array("he", "him", "his") '<--| fill your Variant with values corresponding to the 'gende'r value
    Else
        valsArray = Array("she", "her", "her") '<--| fill your Variant with values corresponding to the 'gende'r value
    End If
    Sheet2.Range("A2:A4").Value = Application.Transpose(valsArray) '<--| write all values in one shot (you need 'Transpose()' to change the "horizontal" Variant array to a "vertical" one and fit the range you're fill values of        
End Sub

---

您还可以使用IIf()函数将其缩短得更多：

Option Explicit

Sub main()
    Dim gender As String

    gender = "Male" '<--| gender initialization for testing purposes

    Sheet2.Range("A2:A4").Value = Application.Transpose(IIf(gender = "Male", Array("he", "him", "his"), Array("she", "her", "her")))        
End Sub