Word Automation错误-服务器计算机不存在

Question

我正在从Excel中自动执行Word，并使用以下代码。 当我第一次运行代码时，我总是能够毫无问题地运行它。 但是，在第二种情况下，我总是会收到此错误。 然后，我必须手动关闭Word文件并再次运行代码，它第一次运行平稳，第二次再次看到错误。

'On Error Resume Next
   Application.ScreenUpdating = False
   Application.EnableEvents = False
   Application.Calculation = xlCalculationManual
   Application.DisplayAlerts = False
   Dim intChoice As Integer
   Dim strPath As String
   Dim objWord As Object
   Set objWord = CreateObject("Word.Application")
   objWord.Visible = True
   Application.FileDialog(msoFileDialogOpen).AllowMultiSelect = False
   intChoice = Application.FileDialog(msoFileDialogOpen).Show
   If intChoice <> 0 Then
 'get the path selected
   strPath = Application.FileDialog( _
    msoFileDialogOpen).SelectedItems(1)
 'opens the document
  Set objdoc = objWord.Documents.Open(strPath)
  With Documents(objdoc)  '''This is where error points to in yellow '''
  Set myrange = ActiveDocument.Content
  ''' My execution code here 
  end with
  objWord.ActiveDocument.SaveAs ThisWorkbook.Path & "\" & 
  ActiveSheet.Range("E3").Value & "_MVR"
  'objWord.ActiveDocument.Close
  objdoc.Close
  objWord.Quit
  Set objdoc = Nothing
  Set objWord = Nothing      
  Application.DisplayAlerts = True
  Application.EnableEvents = True
  Application.Calculation = xlCalculationAutomatic
  Application.ScreenUpdating = True 

Answer 1

按照上面的说明，尝试以下代码：

Option Explicit

Sub AutoWord()

Dim objWord As Object
Dim objdoc As Object
Dim intChoice As Integer
Dim strPath As String
Dim myRange As Range

'On Error Resume Next
Application.ScreenUpdating = False
Application.EnableEvents = False
Application.Calculation = xlCalculationManual
Application.DisplayAlerts = False

Set objWord = CreateObject("Word.Application")
objWord.Visible = True

Application.FileDialog(msoFileDialogOpen).AllowMultiSelect = False
intChoice = Application.FileDialog(msoFileDialogOpen).Show

If intChoice <> 0 Then
    'get the path selected
    strPath = Application.FileDialog(msoFileDialogOpen).SelectedItems(1)

    'opens the document
    Set objdoc = objWord.Documents.Open(strPath)

    With objdoc
        ' all your code related to opened Word document goes here

    End With
    objdoc.SaveAs ThisWorkbook.Path & "\" & ActiveSheet.Range("E3").Value & "_MVR"

    objdoc.Close
End If

objWord.Quit
Set objdoc = Nothing
Set objWord = Nothing

Application.DisplayAlerts = True
Application.EnableEvents = True
Application.Calculation = xlCalculationAutomatic
Application.ScreenUpdating = True

End Sub