XSLT：在父级具有属性时删除子级

Question

当父项具有属性c="string1"时，我希望删除元素d并注释<!-- d -->

输入：

<a>
 <b c="string1">
   <!-- d -->
   <d>
     <e/>
   </d>
   <f/>
 </b>

 <b c="string2">
   <!-- d -->
   <d>
     <e/>
   </d>
   <f/>
 </b>
</a>

所需的输出：

<a>
 <b c="string1">
   <f/>
 </b>

 <b c="string2">
   <!-- d -->
   <d>
     <e/>
   </d>
   <f/>
 </b>
</a>

XSLT：

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0">

   <xsl:output method="xml" indent="yes" omit-xml-declaration="yes"/>

   <!-- Identity transform -->
   <xsl:template match="@*|node()" name="identity">
      <xsl:copy>
         <xsl:apply-templates select="@*|node()"/>
      </xsl:copy>
   </xsl:template>

   <!-- Those templates do not work -->
   <xsl:template match="d[???]" />
   <xsl:template match="comment()="d" />
</xsl:stylesheet>

Answer 1

您可以通过以下一种方式查看它：

<xsl:template match="b[@c='string1']/d" />
<xsl:template match="b[@c='string1']/comment()[.=' d ']" />

或者，如果您愿意：

<xsl:template match="b[@c='string1']">
    <xsl:copy>
        <xsl:apply-templates select="@*|node()[not(self::d or self::comment()[.=' d '])]"/>
    </xsl:copy>
</xsl:template>

---

注意，在给定示例中，注释的值实际上是" d "即用空格包围的字符"d" 。

Answer 2

找到了解决方案。 这两个xsl：templates起作用。

<xsl:template match="d[ancestor::b[@c='string1']]" />
<xsl:template match="comment()[contains(.,'d') and ancestor::b[@c='string1']]" />

我宁愿不使用contains(.,'d')而是在注释文本上使用等式表达式，但是我不知道如何编写该表达式。