Vlookup返回多个值

Question

我试图做Vlookup返回多个值。 但是，该函数的加载时间非常长。 有什么方法可以使其更快？ 我从网上获得了该功能： https : //www.extendoffice.com/documents/excel/2706-excel-vlookup-return-multiple-values-in-one-cell.html

  Function MYVLOOKUP(pValue As String, pWorkRng As Range, pIndex As Long)
  Dim rng As Range
  Dim xResult As String
  xResult = ""
  For Each rng In pWorkRng
   If rng = pValue Then
    xResult = xResult & " " & rng.Offset(0, pIndex - 1)
  End If
 Next
 MYVLOOKUP = xResult
 End Function

这是子代码

 Sub sort()
Dim x As Integer
Dim result As Variant
Dim name As String
 Application.ScreenUpdating = False
  x = 10
 Do Until IsEmpty(Sheet9.Cells(x, 1).Value)
 name = Sheet9.Cells(x, 1).Value
 result = MYVLOOKUP(name, Sheet9.Range("K:M"), 3)
 Sheet9.Cells(x, 4).Value = result
 x = x + 1
 Loop
 End Sub

Answer 1

当您使用传递到UDF中的Sheet9.Range("K:M")作为pWorkRng参数时，将For Each rng In pWorkRng中的For Each rng In pWorkRng循环中使用它。 这意味着您将要检查三个完整的列或3,145,728个单元。 大多数情况下它们都是完全空的，并且对于任何情况下的VLOOKUP来说都不需要两列。 难怪为什么事情进展缓慢。

可以将范围缩小到数据的活动区域，或者使用“相交”将整个列引用缩小到.UsedRange。

Option Explicit

Function MYVLOOKUP(pValue As String, pWorkRng As Range, pIndex As Long)
    Dim rng As Range
    Dim xResult As String

    xResult = vbnullstring
    'the next line trims pWorkRng down to the .UsedRange
    Set pWorkRng = Intersect(pWorkRng, pWorkRng.Parent.UsedRange)

    'if you only want to examione the first column then use the following
    'For Each rng In pWorkRng.columns(1)
    'if you want to look through K, L and M for pValues then use this one,
    For Each rng In pWorkRng
        If rng = pValue Then
            xResult = xResult & " " & rng.Offset(0, pIndex - 1)
       End If
    Next
    MYVLOOKUP = trim(xResult)
 End Function

我添加了一个选项，使其仅在第一列中显示。 您的比较也区分大小写； 您可能确实希望这样做，但是VLOOKUP通常不区分大小写。