如果两个文件中第一列的内容在Unix中匹配，则打印两个文件的列

Question

我有两个文件如下

file1
name|address office
AK|Victoria Street
BK|Admond Street
DK|Business Street

file2
name|address home
AK|Nilofer Villa
ck|Bluewaters
bk|Homingo Apartment

代码的命令或代码行应比较两个文件的第一列，并将这些列合并为name|address office|address home ，并在不匹配的地方替换NA，文件内容可能会很大。 全部输出应如下所示

file3
name|address office|address home
AK|Victoria Street |Nilofer Villa
BK|Admond Street|Homingo Apartment
DK|Business Street|NA
CK|NA|Bluewaters

到目前为止，这是我尝试过的：

awk -F '|' 'NR==FNR{c[$1]++;next};c[$1] > 0' file1 file2

但是上面的代码行没有合并，只是根据列名产生输出作为差异。 太区分大小写
name|address home AK|Nilofer Villa

请帮助，也检查了几个问题，但没有解决我的目的。

Answer 1

您可以使用join命令执行此操作：

$ join -a 1 -a 2 -e NA -o '0,1.2,2.2' -t '|' -i <(sort f1) <(sort f2)
AK|Victoria Street|Nilofer Villa
BK|Admond Street|Homingo Apartment
ck|NA|Bluewaters
DK|Business Street|NA
name|address office|address home

哪里：

• -a 1和-a 2包括两个文件中未连接的行。
• -e和-o一起显示“ NA”字段。 手册页没有提到这一点，但是要使用-e ， 必须指定-o 。 我们仅按以下顺序显示字段：连接列，第一个文件的第二列，第二个文件的第二列。
• -t设置分隔符

当然，我们还必须在使用join之前对文件进行排序（这是必需的），因此我们使用进程替换。 如果您的外壳没有该文件，则可以使用临时文件。

Answer 2

$ cat tst.awk
BEGIN { FS=OFS="|" }
{
    name = (FNR>1 ? toupper($1) : $1)
    if (!seen[name]++) {
        names[++numNames] = name
        vals[name,1] = vals[name,2] = "NA"
    }
    vals[name,ARGIND] = $2
}
END {
    for (nameNr=1; nameNr<=numNames; nameNr++) {
        name = names[nameNr]
        print name, vals[name,1], vals[name,2]
    }
}

$ awk -f tst.awk file1 file2
name|address office|address home
AK|Victoria Street|Nilofer Villa
BK|Admond Street|Homingo Apartment
DK|Business Street|NA
CK|NA|Bluewaters

上面的代码将GNU awk用于ARGIND，而其他awks只需在脚本开始时添加FNR==1{ARGIND++} 。