Prolog-在谓词中搜索列表

Question

我有学生和他们从事的运动的谓词，我想找出哪些学生从事一项特定的运动。 我有这个沙发，但是如果我在列表中输入确切的运动项，并且只有在列表中找到一项运动项时，我才能获得结果。 我不知道如何将其组合起来以找到从事一项运动的学生：

student('Quinton Tarentino', male, 12).
student('Tom Hanks', male, 9).
student('Ed Harris', male, 11).

does_sport('Quinton Tarentino', [soccer, hockey, cricket]).
does_sport('Tom Hanks', []).
does_sport('Ed Harris', [hockey, swimming]).

sports([soccer, hockey, swimming, cricket, netball]).

find(X) :- sports(L), member(X, L).

我尝试过类似的事情：

?- does_sport(X, find(soccer, L)).

这只是返回false。 我知道我需要将运动清单链接到dos_sports谓词，但不确定如何。

任何建议表示赞赏:)

Answer 1

要找出哪些学生从事某项特定运动 ，可以定义一个谓词，如下所示：

student_sport(St,Sp) :-
   does_sport(St,L),      % L is a list of sports student St does
   member(Sp,L).          % Sp is a member of list L

然后，您可以按照问题的意图查询例如足球，如下所示：

   ?- student_sport(St,soccer).
St = 'Quintin Tarentino' ? ;
no

另一方面，曲棍球产生两个结果：

   ?- student_sport(St,hockey).
St = 'Quintin Tarentino' ? ;
St = 'Ed Harris' ? ;
no

如果您想获得一个做曲棍球的学生的清单，则可以使用findall/3如下所示：

   ?- findall(St,student_sport(St,hockey),L).
L = ['Quintin Tarentino','Ed Harris']

或者使用setof/3获取排序列表（如果您碰巧有包含任何事实的事实，则无需重复）：

   ?- setof(St,student_sport(St,hockey),L).
L = ['Ed Harris','Quintin Tarentino']

请注意，在某些Prolog中，您可能必须显式包含一个库以使用member/2 ，例如在Yap中:- use_module(library(lists)). ，而其他人则自动加载它，例如SWI。

编辑：

关于您在评论中提出的问题，让我们从观察到student_sport/2产生一个答案开始。 正如谓词名称所建议的那样，这是有意的，该谓词包含单数形式的“ 学生” ：它描述了学生与非常学生练习的特定运动之间的关系。 这就是为什么我使用findall/3和setof/3添加示例查询的原因，以显示如何在列表中收集解决方案。 您可以轻松地定义谓词students_sport/2 ，该谓词描述特定运动与所有练习该运动的学生的列表之间的关系：

students_sport(L,Sp) :-
   setof(St,student_sport(St,Sp),L).

关于运动紧身裤，您可以选择一个原子来表示这种情况， none选择none ，然后像下面这样向student_sport/2添加一个规则：

student_sport(St,none) :-   % <- rule for the sports-austere
   does_sport(St,[]).       % <- succeeds if the student does no sport
student_sport(St,Sp) :-
   does_sport(St,L),
   member(Sp,L).

这将产生以下结果：

   ?- student_sport(St,none).
St = 'Tom Hanks' ? ;
no

   ?- students_sport(St,none).
St = ['Tom Hanks']

   ?- students_sport(St,hockey).
St = ['Ed Harris','Quintin Tarentino']

   ?- students_sport(St,Sp).
Sp = cricket,
St = ['Quintin Tarentino'] ? ;
Sp = hockey,
St = ['Ed Harris','Quintin Tarentino'] ? ;
Sp = none,
St = ['Tom Hanks'] ? ;
Sp = soccer,
St = ['Quintin Tarentino'] ? ;
Sp = swimming,
St = ['Ed Harris']

最后，关于您的代码与我编写的代码完全相同的假设：结构上有一个相似之处，即谓词find/1具有第一个目标（ sports/1 ），涉及列表，随后使用member/2进行检查该列表中的成员资格。 student_sport/2的第二个规则（或编辑前的单个规则）也具有涉及列表的第一个目标（但不同的是： does_sport/2 ），并随后使用member/2来检查该列表中的成员资格。 相似之处到此结束。 我提供的版本根本不使用sports/1 ，而是在does_sport/2中与特定学生相关的运动列表。 请注意， find/1并未描述与学生的任何联系。 此外，您的查询?- does_sport(X, find(soccer, L)). 表示您似乎期望某种返回值。 您可以将谓词视为返回true或false函数，但这在对Prolog进行编程时通常不是很有用。 参数find(soccer,L)并未像您期望的那样被调用，而是从字面上作为参数传递。 并且由于您的事实不包括以下方面的内容

does_sport(*SomeStudentHere*, find(soccer,L)).

您的查询失败。