Prolog在列表中重复一个单词

Question

我有一个Prolog代码，可以复制整个列表，但是我想要的是仅复制一个单词（例如“ a”）。 例如;

dups([],[]).
dups([H|T],[H,H|Y]) :-
    dups(T,Y). 

我的代码重复了列表[a,b]例如=> [a, a ,b ,b] 。

但是我想要的是重复列表[a, b]例如=> [a, a, b] 。

Answer 1

由于您正在描述列表，因此您可以选择使用DCG。 请考虑以下规则：

x_dup(_X,[]) -->       % if the input list is empty
   [].                 % the output list is empty
x_dup(X,[X|Ys]) -->    % if X and the head of the list are equal
   [X,X],              % X is twice in the output list
   x_dup(X,Ys).        % the same holds for X and the tail
x_dup(X,[Y|Ys]) -->    % if X and the head of the input list
   {dif(X,Y)},         % are different
   [Y],                % the head is once in the output list
   x_dup(X,Ys).        % the same holds for X and the tail

如果您只想复制列表的开头，则可以这样定义调用谓词：

dups([],[]).                    % <- only for empty list
dups([X|Xs],L) :-
   phrase(x_dup(X,[X|Xs]),L).

第一条规则仅用于处理空列表。 如果您不希望谓词涵盖这种情况，则只需忽略第一条规则。 用您的示例查询将产生所需的结果：

   ?- dups([a,b,a,a,c,c,c],L).
L = [a,a,b,a,a,a,a,c,c,c] ? ;
no

另外，您可以定义调用谓词，以便可以复制任意元素。 在这种情况下，您需要一个附加参数来指定要复制的元素：

dups(X,L1,L2) :-
   phrase(x_dup(X,L1),L2).

一些示例查询：

   ?- dups(a,[a,b,a,a,c,c,c],L).
L = [a,a,b,a,a,a,a,c,c,c] ? ;
no
   ?- dups(b,[a,b,a,a,c,c,c],L).
L = [a,b,b,a,a,c,c,c] ? ;
no
   ?- dups(c,[a,b,a,a,c,c,c],L).
L = [a,b,a,a,c,c,c,c,c,c] ? ;
no
   ?- dups(d,[a,b,a,a,c,c,c],L).
L = [a,b,a,a,c,c,c]