VBA将数据传输到另一个工作簿

Question

在附图中，这是最终目标。

我想使用VBA将数据从一张纸传输到另一张纸。 到目前为止，当我单击“提交”时，“国家/地区”，“名称”，“姓”的数据将正确发送到名为“数据”的工作表。 但是，我不确定如何在名为“数据”的工作表中填充“种族”字段。 我知道我应该使用if语句，但是我不确定如何将其合并到VBA代码中。

这是目前的vba代码。

Private Sub CommandButton1_Click()

     Dim Country As String, Name As String, Surname As String, Race As String
     Worksheets("form").Select

     Country = Range("B4")
     Name = Range("B6")
     Surname = Range("B7")
     Race = Range("B13")

     Worksheets("data").Select
     Worksheets("data").Range("A1").Select
     If Worksheets("data").Range("A1").Offset(1, 0) <> "" Then
          Worksheets("data").Range("A1").End(xlDown).Select
     End If

     ActiveCell.Offset(1, 0).Select
     ActiveCell.Value = Country
     ActiveCell.Offset(0, 1).Select
     ActiveCell.Value = Name
     ActiveCell.Offset(0, 1).Select
     ActiveCell.Value = Surname
     ActiveCell.Offset(0, 1).Select
     ActiveCell.Value = Race

     Worksheets("form").Select
     Worksheets("form").Range("A4").Select
End Sub

我是VBA的新手，在此方面提供的任何帮助将不胜感激。

Answer 1

这是给你的东西，但是我对你有一些批评

1）选择/激活/复制/粘贴都是坏习惯。 您最终要编写大量无意义的代码以充分利用它，并且降低了整个过程的速度。 如果您要与许多事物进行交互，那么这很重要。

2）。 表单选项卡上的Race看起来是一个合并的单元格。 我的代码段假设种族实际上是单元格b13，c13和d13。 合并的单元格很烦人，可能是导致问题的根本原因。 否则我可能完全错了，而您真的是个超级新手。 无论哪种方式，您都可以学习一些东西。

Private Sub CommandButton1_Click()
     Dim Country As String, Name As String, Surname As String, Race As String
     dim ws as worksheet, wb as workbook, ws1 as worksheet

     set wb = ThisWorkbook
     set ws = wb.Sheets("form")
     set ws1 = wb.Sheets("data")
     Country = ws.Range("B4").value
     Name = ws.Range("B6").value
     Surname = ws.Range("B7").value

     If ws.Range("B13").Value <> "" Then Race = "White"
     If ws.Range("C13").Value <> "" Then Race = "Black"
     If ws.Range("D13").Value <> "" Then Race = "Asian"

     ws1.Cells(ws1.Rows.Count,1).End(xlUp).Offset(1,0).Value = Country
     ws1.Cells(ws1.Rows.Count,1).End(xlUp).Offset(0,1).Value = Name
     ws1.Cells(ws1.Rows.Count,1).End(xlUp).Offset(0,2).Value = Surname
     ws1.Cells(ws1.Rows.Count,1).End(xlUp).Offset(0,3).Value = Race
End Sub

实际上，我有点喜欢这种更好的变量。 不必使用无意义的变量来存储值，您可以将值存储在数组中并一次将它们全部移走，我也认为这样可以节省大量开销。 当然，我知道我使用了相同数量的fo变量来制作图纸/工作簿对象，但是您可以将它们写得很长（即使那时我只是一堆文字，我实际上还是喜欢这样做）。

我还提供了一些检查，以防万一选择了多个种族，或者根本没有一个种族。

Private Sub here()

    Dim ws As Worksheet, wb As Workbook, ws1 As Worksheet
    Dim arr(0, 4) As String

    Set wb = ThisWorkbook
    Set ws = wb.Sheets("Sheet1")
    Set ws1 = wb.Sheets("Sheet2")
    arr(0, 0) = ws1.Cells(ws1.Rows.Count, 1).End(xlUp).Value + 1
    arr(0, 1) = ws.Range("B4").Value
    arr(0, 2) = ws.Range("B6").Value
    arr(0, 3) = ws.Range("B7").Value

    If (ws.Range("B13").Value <> "" And ws.Range("C13").Value <> "") _
        Or (ws.Range("B13").Value <> "" And ws.Range("D13").Value <> "") _
            Or (ws.Range("D13").Value <> "" And ws.Range("C13").Value <> "") Then
        arr(0, 4) = "Mixed Race"
    Else
        arr(0, 4) = IIf(ws.Range("B13").Value <> "", "White", _
            IIf(ws.Range("C13").Value <> "", "Black", _
                IIf(ws.Range("D13").Value <> "", "Asian", "Must Be Non-Human")))
    End If

    ws1.Range(ws1.Cells(ws1.UsedRange.Rows.Count + 1, 1), _
        ws1.Cells(ws1.UsedRange.Rows.Count + 1, 5)).Value2 = arr

End Sub