命名表中单元格的值

Question

如何使用可读的公式（即其中名称/名称而不是索引引用行/单元格的公式）获得命名表中特定单元格的值？

在上面的图片中，我要显示表Financials的单元格(Income, Feb)的值。 我可以使用什么语法？

Answer 1

如前所述，您可以使用用户定义的函数（例如

Public Function Financials(month As String, item As String) As String

'Object to represent the table    
Dim lo As ListObject: Set lo = Range("Table1").ListObject

'Integers to act as coordinates    
Dim x As Integer, y As Integer

'Find the column
x = lo.HeaderRowRange.Find(month).Column - lo.HeaderRowRange.Column + 1

'Find the row
y = lo.DataBodyRange.Columns(1).Find(item).Row - lo.HeaderRowRange.Row

' Return the value at the coordinates x,y
Financials = lo.DataBodyRange(y, x).Value

End Function

（使用工作簿中的表名更新Range("Table1").ListObject ，或者可以向该函数添加另一个参数）

然后，您将在工作簿单元格（如本示例）中调用此函数

=Financials("Feb", "Profit")

Answer 2

我发现很难相信Microsoft并未一直为客户提供解决方案！

借鉴@ maxhob17的提示，这是适用于任何命名表的通用解决方案：

Public Function TLookup(tablename As String, key As String, col As String)
    'From a table, find the corresponding value for a key (in the first column)

    'Object to represent the table
    Dim lo As ListObject: Set lo = range(tablename).ListObject

    'Integers to act as coordinates
    Dim x As Integer, y As Integer

    'Find the column
    x = lo.HeaderRowRange.Find(col).column - lo.HeaderRowRange.column + 1

    'Use the key to find the row
    y = lo.DataBodyRange.Columns(1).Find(key).Row - lo.HeaderRowRange.Row

    ' Return the value at the coordinates x,y
    TLookup = lo.DataBodyRange(y, x).Value

End Function

在VB窗口中，将以上代码插入模块中。 切记以xlsm格式保存Excel文件。

然后，您应该可以在表格中插入以下公式：

=TLookup("Financials", "Feb", "Profit")

这个把戏将改变我的生活。 可能会改变您的。 它不能简单，可以吗？

我还在github中记录了该解决方案 。