在Excel中创建工作表的超链接列表

Question

我知道如何用特定的超链接填充到工作表中所有工作表的工作表，但是如何排除某些工作表呢？

我在下面列出了我正在使用的VB。 我想排除某些表格，例如“测试结果”等。

Sub GetHyperlinks()
    Dim ws As Worksheet
    Dim i As Integer

    i = 9

    For Each ws In ThisWorkbook.Worksheets
        ActiveWorkbook.Sheets("overview").Hyperlinks.Add _
        Anchor:=ActiveWorkbook.Sheets("overview").Cells(i, 1), _
        Address:="", _
        SubAddress:="'" & ws.NAme & "'!A1", _
        TextToDisplay:=ws.NAme

        i = i + 1
    Next ws
End Sub

Answer 1

Sub GetHyperlinks()
    Dim arrExclude
    Dim ws As Worksheet
    Dim i As Integer

    'Sheets to be excluded from linking
    arrExclude = Array("Test Results", "some other sheet", "overview")

    i = 9

    For Each ws In ThisWorkbook.Worksheets
        'test to see if not excluded
        If IsError(Application.Match(ws.Name, arrExclude, 0)) Then
            ActiveWorkbook.Sheets("overview").Hyperlinks.Add _
                Anchor:=ActiveWorkbook.Sheets("overview").Cells(i, 1), _
                Address:="", _
                SubAddress:="'" & ws.Name & "'!A1", _
                TextToDisplay:=ws.Name
            i = i + 1
        End If 'include this sheet
    Next ws
End Sub