Perl：如何在不创建数组副本的情况下取消引用数组？

Question

当我使用@ $ arrayRef或@ {$ arrayRef}取消引用数组时，它似乎会创建该数组的副本。 是否有解引用数组的正确方法？

此代码...

sub updateArray1 {
        my $aRef = shift;
        my @a = @$aRef;
        my $aRef2 = \@a;

        $a[0] = 0;
        push(@a, 3);
        my $aRef3 = \@a;

        print "inside1 \@a: @a\n";
        print "inside1 \$aRef: $aRef\n";
        print "inside1 \$aRef2: $aRef2\n";
        print "inside1 \$aRef3: $aRef3\n\n";
}

my @array = (1, 2);

print "before: @array\n";
my $ar = \@array;
print "before: $ar\n\n";

updateArray1(\@array);

print "after: @array\n";
$ar = \@array;
print "after: $ar\n\n";

...具有输出...

before: 1 2
before: ARRAY(0x1601440)

inside1 @a: 0 2 3
inside1 $aRef: ARRAY(0x1601440)
inside1 $aRef2: ARRAY(0x30c1f08)
inside1 $aRef3: ARRAY(0x30c1f08)

after: 1 2
after: ARRAY(0x1601440)

如您所见，@ $ aRef创建一个新的指针地址。

我发现解决此问题的唯一方法是仅使用引用：

sub updateArray2 {
        my $aRef = shift;

        @$aRef[0] = 0;
        push(@$aRef, 3);

        print "inside2 \@\$aRef: @$aRef\n";
        print "inside2 \$aRef: $aRef\n\n";
}

updateArray2(\@array);

print "after2: @array\n";
$ar = \@array;
print "after2: $ar\n\n";

产生输出：

inside2 @$aRef: 0 2 3
inside2 $aRef: ARRAY(0x1601440)

after2: 0 2 3
after2: ARRAY(0x1601440)

是否可以在不复制整个数组的情况下取消对数组的指针的引用？ 还是我需要将其保留在参考表中并在我想使用它时随时取消引用？

Answer 1

取消引用不会创建副本，如以下示例所示：

my @a = qw(a b c);
my $ra = \@a;
@{$ra}[0,1] = qw(foo bar);  # dereferencing is done here but not copying
print @$ra; # foo bar c
print @a; # foo bar c

相反， 将 （取消引用的）数组分配给另一个数组将创建副本 ：

my @a = qw(a b c);
my $ra = \@a;
my @newa = @$ra;   # copy by assigning
$newa[0] = 'foo';
print @newa; # foo b c
print @a; # a b c

将一个数组分配给另一个数组本质上说，旧数组中的所有元素也应分配给新数组-这与为原始数组使用不同的名称不同。 但是，将一个数组引用分配给另一个数组引用只会使旧数组具有不同的名称，即复制数组引用与复制数组内容。

请注意，这似乎与Python或Java等语言不同，因为在这些语言中，变量仅描述数组对象，即，对数组的引用而不是数组的内容。

Answer 2

使用实验性重混音功能：

use 5.022;
use warnings;
use feature 'refaliasing';
no warnings 'experimental::refaliasing';
\my @array = $array_ref;

但是，为什么不保留它作为参考呢？ 对于数组，您无能为力，对数组引用也无能为力。

Answer 3

我的观察/理解是，它与名称有关-如果您给取消引用的数组起一个名称，则它将被复制，因为perl变量是通过复制传递的，它们与C ++中的结构完全一样。 但是，即使复制了引用（类似于C / C ++中的int *newPtr = oldPtr ），该引用的每个副本也将指向同一对象。 仅当您通过引用或通过内联取消引用来访问其元素时，才会修改原始数组。 我认为这没有任何办法。 当您调用my @foo = @{$barRef} ，您正在调用副本构造函数。 标量是相同的-当您通过$_[0] = val修改参数时，调用方的变量也会被修改。 但是，如果给变量命名，例如my $arg = $_[0] ，则会创建一个副本。

也就是说，有一些便捷的方法可以处理您应该知道的引用，如果您还没有使用它们的话：

$arrayRef->[0] = "foo";
$hashRef->{key} = "value";
$codeRef->(); # execute a code reference

但是确实，由于push无法处理引用，因此您需要像在示例中一样使用内联取消引用。

如果您真的要创建一个引用数组，那么有一种古老的perl技术可以做到这一点。 您不应该在现代代码中使用它。 它在这里描述： https : //perldoc.perl.org/perlsub.html#Passing-Symbol-Table-Entries-(typeglobs）

Answer 4

该代码明确要求复制数据

my @a = @$aRef;

为了创建一个新的数组@a 。

我不清楚您的意思是什么

是否可以在不复制整个数组的情况下取消对数组的指针的引用？

如果在某个操作中需要所有值–制作另一个数组，或打印它们，或将它们发送以进行sort或map ... –则可以复制数据，或者如果是通过指针完成，则可能不需要。 如果复制了数据（即使仅在堆栈上），则它与我们拥有数组的情况相同，实际上是“取消引用”。

这是一个关于如何处理数据的问题，人们通常不能说太多。

---

如果您需要访问特定的元素（或切片），然后取消引用，则不要创建新的数组。

但是，请不要通过@$aRef[0] = 0; 即使碰巧是合法的，但是通过

$$aRef[0] = 0;
$aRef->[0] = 0;

我发现第二个版本通常更安全，不会出现愚蠢的错误，而且更清晰。