使用 VBA 仅引用 Excel 表数据主体范围的一部分

Question

我找到了引用表中的整行/列或单个单元格的解决方案（例如 The VBA Guide To ListObject Excel Tables ），但不是特定范围。

示例：Table1 的 DataBodyRange 是 3 列和 10 行，我需要在每列中绘制第 4-10 行的数据（以编程方式，因为表格是动态的，我希望能够重新绘制图表，如果列添加/删除）。

我希望语法类似于

Sub reDrawChart()

Set sourcedata = ActiveSheet.ListObjects("Table1")
Set cht = Worksheets("Sheet1").ChartObjects(1).Chart

'Delete existing series
cht.ChartArea.ClearContents 

'Add new series
With cht.SeriesCollection.NewSeries
    For i = 1 To nColumns
        .Name = sourcedata.HeaderRowRange(i)
        .Values = sourcedata.DataBodyRange(4:10, i) '<-- Touble spot
    Next i
End With

End Sub

但这是行不通的。 有没有办法用这一行来做我想要做的事情？ 我应该解决它并寻求不同的解决方案吗？

我还想避免使用 .Select ，因为在 Mac OS 上感觉任何使 VBA 口吃的代码都有 50/50 的机会崩溃到桌面。

Answer 1

试试这个循环而不是你的：

    For i = 1 To sourceData.ListColumns.count
      With cht.SeriesCollection.NewSeries
        .name = sourceData.ListColumns(i).name
        .values = sourceData.ListColumns(i).DataBodyRange. _
          Offset(3).Resize(sourceData.ListRows.count - 3)
      End With
    Next i

Answer 2

您可以ListColumns代表的ListColumns并使用 Offset 和 Resize 从每个 ListColumn 的DataBodyRange中获取一组特定的行。

对于第 4 行到第 10 行，您需要偏移 3 行，然后调整大小 7 行。 如果感兴趣的行数发生变化，或者第一行索引发生变化，您可以在下面的示例代码中调整这些数字：

Option Explicit

Sub TableSection()

    Dim ws As Worksheet
    Dim lst As ListObject
    Dim lcl As ListColumn
    Dim i As Long
    Dim var As Variant

    Set ws = ThisWorkbook.Worksheets("Sheet1") '<-- change to your sheet
    Set lst = ws.ListObjects("Table1") '<-- change to your table

    For Each lcl In lst.ListColumns
        ' change 3 and 7 depending on the rows you are interested in
        var = lcl.DataBodyRange.Offset(3, 0).Resize(7, 1)
    Next lcl

End Sub