Perl从日志中收集具有特定内容的XML代码段

Question

我从另一个stackoverflow问题中复制了一个脚本，但是它似乎替换了变量的内容，有人可以指出我该错误吗？ 如果我删除了“> OK <”的if检查，它会将整个xml打印到一个文件中；如果我放回if，它只打印包含“> OK <”的行，为什么$ xml变量被=〜？

# Example usage:
# perl script.pl data.xml RootTag > RootTag.xml

use strict;
use warnings;

my $tag = pop;

while (<>){
  if ( s/.*(<$tag>)/$1/ .. s/(<(\/)$tag>).*/$1/ ) {
    my $xml = $_;
    if ($xml =~ m/>OK</) {
        print "$xml";
    }
  }
}

输入文件的示例可以是

reioirioree
brebreberbre
rbebrbebre
<test>
<id>1</id>
<status>OK</status>
</test>
bbrtbtrbt
rtbtrb
<test>
<id>2</id>
<status>KO</status>
</test>
brtoibjtrbi
bebbetreb
<test>
<id>3</id>
<status>OK</status>
</test>
dfbreberbreb
berbrebre

在这种情况下，如果我们使用“ test”作为参数，我想跟踪以下输出

<test>
<id>1</id>
<status>OK</status>
</test>
<test>
<id>3</id>
<status>OK</status>
</test>

Answer 1

目的是捕获包含特定模式（ >OK< ）的整个tag 。

这是详细说明细节的分步方法。 我保留您的程序界面。

use strict;
use warnings;

my $tag = pop;

my ($inside_tag, $found, @buff);

while (<>)
{
    if (s/.*(<$tag>)/$1/) {
        $inside_tag = 1;
    }   
    elsif (s|(</$tag>).*|$1|) {  #/
        $inside_tag = 0;
        if ($found) { 
            print @buff, $_;
            $found = 0;
        }
        @buff = ();
    }   

    next unless $inside_tag;

    push @buff, $_; 

    $found = 1 if />OK</;
}

在开始标签上，我们设置标记在标签内。 在结束标签，我们取消它，如果标记已被$found我们打印缓冲区（并取消标记的标志）。 我们在这里清除缓冲区。

然后，如果标签之外，我们将跳过迭代。 否则，将该行添加到缓冲区并测试该行上的标记。

---

在此问题中使用范围的一个小问题是，我们必须知道何时处于结束标记行，并且也想知道开始行。 然后，我们需要进一步测试，触发器不再那么干净。 我们可以使用..运算符返回的序列号

返回的值是空字符串（如果为false）或序列号（从1开始）为true（真）。 将为遇到的每个范围重置序列号。 范围中的最后一个序列号附加了字符串"E0" ，这不会影响其数值，但是如果要排除端点，则会为您提供一些搜索内容。 您可以通过等待序列号大于1来排除起点。

它会像

if (my $seq = /BEG/ .. /END/) 
{
    if ($seq == 1)        {  # first line of range
        # ...
    }
    elsif ($seq =~ /EO$/) {  # last line of range
        # ...
    }
    else  { ... }            # inside

而且我看不出这比手动保持状态更为清楚或更好。