如何使用 Terraform 将多个 IAM 策略附加到 IAM 角色？

Question

我想将多个 IAM 策略 ARN 附加到单个 IAM 角色。

一种方法是创建具有所有策略（多个策略）权限的新策略。

但是在 AWS 中，我们有一些预定义的 IAM 策略，例如AmazonEC2FullAccess 、 AmazomS3FullAccess等。我想将这些策略组合用于我的角色。

我在 Terraform 文档中找不到这样做的方法。

根据文档，我们可以使用aws_iam_role_policy_attachment将策略附加到角色，但不能将多个策略附加到角色，因为这可通过 AWS 控制台获得。

请让我知道是否有一种方法可以做到这一点，或者它是否仍然是一个要添加的功能。

我使用的 Terraform 版本是v0.9.5

Answer 1

感谢 Krishna Kumar R 的提示。

我从你的回答中得出了一个更精致的答案。

# Define policy ARNs as list
variable "iam_policy_arn" {
  description = "IAM Policy to be attached to role"
  type = "list"
}

# Then parse through the list using count
resource "aws_iam_role_policy_attachment" "role-policy-attachment" {
  role       = "${var.iam_role_name}"
  count      = "${length(var.iam_policy_arn)}"
  policy_arn = "${var.iam_policy_arn[count.index]}"
}

最后，应在 *.tfvars 文件或命令行中使用 -var 指定策略列表，例如：

iam_policy_arn = [ "arn:aws:iam::aws:policy/AmazonEC2FullAccess", "arn:aws:iam::aws:policy/AmazonS3FullAccess"]

Answer 2

对于 Terraform 版本 >= 0.12，添加多个策略的最简洁方法可能是这样的：

resource "aws_iam_role_policy_attachment" "role-policy-attachment" {
  for_each = toset([
    "arn:aws:iam::aws:policy/AmazonEC2FullAccess", 
    "arn:aws:iam::aws:policy/AmazonS3FullAccess"
  ])

  role       = var.iam_role_name
  policy_arn = each.value
}

如 Pranshu Verma 的回答所述，策略列表也可以放入变量中。

使用for_each count的优点是，列表中的插入会被 terraform 正确识别，因此它实际上只会添加一个策略，而使用 count 将更改插入后的所有策略（ 此博客中有详细描述） 发布)

Answer 3

你有没有尝试过这样的事情：

resource "aws_iam_role" "iam_role_name" {
  name = "iam_role_name"
}

resource "aws_iam_role_policy_attachment" "mgd_pol_1" {
  name       = "mgd_pol_attach_name"
  role       = "${aws_iam_role.iam_role_name.name}"
  policy_arn = "${aws_iam_policy.mgd_pol_1.arn}"
}

resource "aws_iam_role_policy_attachment" "mgd_pol_2" {
  name       = "mgd_pol_attach_name"
  role       = "${aws_iam_role.iam_role_name.name}"
  policy_arn = "${aws_iam_policy.mgd_pol_2.arn}"
}

Answer 4

添加另一个选项，类似于例外答案，但不是：

policy_arn = "${var.iam_policy_arn[count.index]}"

您可以使用元素功能：

policy_arn = "${element(var.iam_policy_arn,count.index)}"

我认为在某些情况下（例如具有大量代码的项目），这可能更具可读性。

Answer 5

这是我如何做到的一个例子：

resource "aws_iam_group_policy_attachment" "policy_attach_example" {
  for_each   = aws_iam_policy.example
  group      = aws_iam_group.example.name
  policy_arn = each.value["arn"]
}

所以基本上“aws_iam_policy.example”是我以相同方式制定的政策列表，for_each

希望这对你有帮助，我知道我来晚了，但我遇到了类似的问题