除非我中断用户表单初始化，否则事件处理类不会触发

Question

这是以下问题的后续： Can't set Userform.KeyPreview to true

总结一下：目标是构建一个带有一些命令按钮和一个包含复选框的框架的表单。 复选框在框架中的userform_initialize处动态填充，因此用户可以滚动浏览它们。 我的问题是键盘快捷键。 不可能为每个复选框强制编写 KeyDown 处理程序，因为我不知道哪些会存在。 不幸的是，Excel 不支持KeyPreview所以我不得不模拟我自己的版本。 感谢@UGP 为我提供了看似有效但并不完全有效的途径...

首先，这是我的类模块clsReasonPickKP 。 我为每个复选框创建一个新实例来监听KeyDown事件：

Option Explicit

Dim WithEvents vChkBx As MSForms.CheckBox

Friend Sub initializeListener(cControl As control)
Set vChkBx = cControl
End Sub

Private Sub vChkBx_KeyDown(ByVal keyCode As MSForms.ReturnInteger, ByVal shift As Integer)
frm2.keyChooser keyCode
End Sub

行frm2.keyChooser keyCode启动位于用户frm2.keyChooser keyCode代码模块中的快速子。 代码如下：

Public Sub keyChooser(ByVal keyCode As MSForms.ReturnInteger)
Select Case keyCode
    Case vbKeyEscape: cancelBtn_Click
    Case vbKeyReturn: completeDecision_Click
    Case vbKeyN: customizeNote_Click
    Case vbKeyS: resetDecisionNote_Click
    Case vbKeyR: chkRefGrnds_Click
End Select
End Sub

我已经复制了下面UserForm_Initialize子的相关部分。 循环为每个创建复选框和事件侦听器。

Sub UserForm_Initialize()
Dim x As Long, maxWidth as Long
Dim cControl As control
Dim keyPreviewCollection As New Collection
Dim keyPreviewer As clsReasonPickKP
For x = 1 To dTbl.Rows.Count - 1
    Set cControl = chkBoxFrame.Controls.Add("Forms.CheckBox.1", "chkBox" & x, True)
    With cControl
        .AutoSize = True
        .WordWrap = False
        .Left = 10
        .Top = 16 * x - 12
        .Caption = dTbl(x, 1).Value
        If .Width > maxWidth Then maxWidth = .Width
    End With
Set keyPreviewer = New clsReasonPickKP
keyPreviewer.initializeListener cControl
keyPreviewCollection.Add keyPreviewer
Next x
'Additional initialization code here
End Sub

奇怪的是，除非我在keyPreviewCollection.Add keyPreviewer之后破坏代码，否则监听器似乎不会处理该事件。 例如，如果我在Next x或x > 1处设置断点，然后完成初始化，那么当表单完成初始化并出现时，侦听器调用keyChooser并且一切正常； 如果我不那样破坏代码，它就不会捕获事件或调用 sub 等。

为了keyPreviewer故障，我尝试不将keyPreviewer添加到集合中，然后无论我是否中断或何时中断，侦听器也不起作用。 似乎将对象添加到集合中，并在将其添加到集合后处于代码中断模式，以某种方式使侦听器捕获事件。

同样有趣的是，如果我在vChkBx_KeyDown模块中放置一个断点，它会在引发事件时中断（假设如上所述的适当中断）。 但是，在我运行代码之后，它会在KeyDown事件引发时停止处理它。

如果有帮助，我目前正在使用 Excel 2010。

有人知道发生了什么吗？ 知道如何解决这个问题，即使使用不同的代码方法？

一如既往地感谢大家的帮助。

Answer 1

原来，问题就这么简单，就在我眼前。 我只需要在我的用户表单代码模块中公开keyPreviewer和keyPreviewCollection变量。

这仍然不能回答为什么在将对象添加到集合后破坏代码执行使 VBA 将其视为公共的，但很高兴一切正常。

Answer 2

DoEvents 可能是票。 请参阅下面的文章：

https://www.automateexcel.com/vba/doevents/