接受批处理文件的自定义输入吗？

Question

我正在使用DOS批处理脚本。

有没有一种方法可以接受用户的输入，该输入可以是自定义整数范围，例如1-250？

我想接受用户的一系列工作站名称，例如1-250，该范围内的每个数字都可以循环通过，并根据该数字发送到不同的命令。

工作站名称可以采用以下三种可能的数字格式：w0001，w0010或w0100。 因此，如果我输入1-250，则可能是这3种格式中的任何一种：3个前导零代表一位数字，2个前导零代表两位数字，或1个前导零代表三位数。

像这样，以SC查询命令为例：

set "range="

set /p range="Please enter workstation range:"

DO(if %range% > 0)

(

IF %range% = 1 
DO SC \\W000%range% query

IF %range% = 10
DO SC \\W00%range% query

IF %range% = 100
DO SC \\W0%range% query

)

我正在研究FOR / L或FOR / F，但它们似乎只能在“设置”字段中接受（1,1,10）或（filename.txt）。之类的内容。 我需要用户能够输入诸如1-250之类的简单内容。

提前致谢。

Answer 1

我不清楚你在问什么。

要迭代输出四个数字的范围，请尝试以下操作：

@echo off & setlocal enabledelayedexpansion
set "range="
set /p range="Please enter workstation range:"
set "start="
set "stop="
for /f "tokens=1,2 delims=-" %%A in ("%range%") do Set /A "start=%%A+10000,stop=%%B+10000"
if defined stop if %start% leq %stop% for /l %%L in (%start%,1,%stop%) do (
    set "L=%%L"
    Echo Processing \\w!L:~-4!
    Rem do whatever you like with the value 
)

样品运行：

> SO_46410755.cmd
Please enter workstation range:1-120
Processing \\w0001
Processing \\w0002
Processing \\w0003
Processing \\w0004
Processing \\w0005
Processing \\w0006
Processing \\w0007
Processing \\w0008
Processing \\w0009
Processing \\w0010
Processing \\w0011
Processing \\w0012
...
Processing \\w0096
Processing \\w0097
Processing \\w0098
Processing \\w0099
Processing \\w0100
Processing \\w0101
Processing \\w0102
...
Processing \\w0117
Processing \\w0118
Processing \\w0119
Processing \\w0120

• for /f的第一个将减号/连字符处的var range内容分为两部分，并将第一个存储到start加10000，第二个存储到stop也加10000。
• for /l迭代从开始（使用步骤1）到停止的范围。
• 要使用子字符串，我们需要一个普通变量，因此变量%%L的存储在变量L
• 因为这发生在（括号中的代码块）中，所以我们需要延迟扩展