清单的球拍模式匹配

Question

我正在尝试与列表进行模式匹配，但是由于某些原因，当我执行以下操作时会得到意外的匹配：

> (define code '(h1 ((id an-id-here)) Some text here))
> (define code-match-expr '(pre ([class brush: python]) ...))
> (match code
    [code-match-expr #t]
    [_ #f])
#t

问题：为什么code与code-match-expr ？

实际用例

我在Racket REPL中进行了尝试，因为我实际上想解决另一个实际问题：使用Pollen的pygments包装函数突出显示代码，这些代码稍后将以HTML输出。 为此，我编写了以下代码，以解决问题：

(define (read-post-from-file path)
  (Post-from-content (replace-code-xexprs (parse-markdown path))))

(define (replace-code-xexprs list-of-xexprs)
  ;; define known languages
  (define KNOWN-LANGUAGE-SYMBOLS
    (list 'python
          'racket
          'html
          'css
          'javascript
          'erlang
          'rust))
  ;; check if it matches for a single language's match expression
  ;; if it mathces any language, return that language's name as a symbol
  (define (get-matching-language an-xexpr)
    (define (matches-lang-match-expr? an-xexpr lang-symbol)
      (display "XEXPR:") (displayln an-xexpr)
      (match an-xexpr
        [`(pre ([class brush: ,lang-symbol]) (code () ,more ...)) lang-symbol]
        [`(pre ([class brush: ,lang-symbol]) ,more ...) lang-symbol]
        [_ #f]))

    (ormap (lambda (lang-symbol)
             ;; (display "trying to match ")
             ;; (display an-xexpr)
             ;; (display " against ")
             ;; (displayln lang-symbol)
             (matches-lang-match-expr? an-xexpr lang-symbol))
           KNOWN-LANGUAGE-SYMBOLS))

  ;; replace code in an xexpr with highlightable code
  ;; TODO: What happens if the code is in a lower level of the xexpr?
  (define (replace-code-in-single-xexpr an-xexpr)
    (let ([matching-language (get-matching-language an-xexpr)])
      (cond [matching-language (code-highlight an-xexpr matching-language)]
            [else an-xexpr])))

  ;; apply the check to all xexpr
  (map replace-code-in-single-xexpr list-of-xexprs))

(define (code-highlight language code)
  (highlight language code))

在此示例中，我将解析具有以下内容的降价文件：

# Code Demo

```python
def hello():
    print("Hello World!")
```

我得到以下xexpr ：

1。

(h1 ((id code-demo)) Code Demo)

2。

(pre ((class brush: python)) (code () def hello():
    print("Hello World!")))

但是，由于某种原因，这些都不匹配。

Answer 1

match是语法，不评估模式。 由于code-match-expr是一个符号，它将把整个表达式（评估code结果）绑定到变量code-match-expr并在模式匹配时评估其余的表达式。 结果将始终为#t 。

请注意，第二个模式符号_是相同的模式 。 它也匹配整个表达式，但是_的特殊之处在于它不会像code-match-expr那样被绑定。

重要的是，永远不要使用您定义的变量code-match-expr ，但是由于match绑定了一个具有相同名称的变量，因此在进行match原始绑定将被遮盖。

可以正常工作的代码如下所示：

(define (test code)
  (match code 
    [`(pre ([class brush: python]) ,more ...) #t]
    [_ #f]))

(test '(h1 ((id an-id-here)) Some text here))
; ==> #f

(test '(pre ((class brush: python))))
; ==> #t

(test '(pre ((class brush: python)) a b c))
; ==> #t

正如您所看到的,more ...表示零个或多个，并且忽略哪种括号，因为在Racket []中与()和{} 。

编辑

您仍然有点落后。 在此代码中：

(define (matches-lang-match-expr? an-xexpr lang-symbol)
  (display "XEXPR:") (displayln an-xexpr)
  (match an-xexpr
    [`(pre ([class brush: ,lang-symbol]) (code () ,more ...)) lang-symbol]
    [`(pre ([class brush: ,lang-symbol]) ,more ...) lang-symbol]
    [_ #f]))

打包模式后，由于未对lang-symbol进行引用，因此它将匹配原子的任何内容，并将其绑定为该子句中的变量。 它与具有相同名称的绑定变量无关 ，因为match不使用变量，而是创建变量。 您返回变量。 从而：

(matches-lang-match-expr? '(pre ([class brush: jiffy]) bla bla bla) 'ignored-argument)
; ==> jiffy

这是您想要做的事情：

 (define (get-matching-language an-xexpr)
    (define (get-language an-xexpr)
      (match an-xexpr
        [`(pre ([class brush: ,lang-symbol]) (code () ,more ...)) lang-symbol]
        [`(pre ([class brush: ,lang-symbol]) ,more ...) lang-symbol]
        [_ #f]))
    (let* ((matched-lang-symbol (get-language an-xexpr))
           (in-known-languages (memq matched-lang-symbol KNOWN-LANGUAGE-SYMBOLS)))
      (and in-known-languages (car in-known-languages))))

同样，。 match滥用准引用与创建列表结构完全不同。 它使用它们来匹配文字并将未加引号的符号捕获为变量。

Answer 2

确保您清楚匹配的内容。 在Racket x表达式中，属性名称是符号，但值是字符串。 因此，您要匹配的表达式将类似于(pre ([class "brush: js"])) ___) - 不是 (pre ([class brush: js]) ___) 。

要匹配该字符串并提取"brush: "之后的部分，可以使用pregexp匹配模式。 这是Frog用于提取要提供给Pygments的语言的代码段 ：

(for/list ([x xs])
  (match x
    [(or `(pre ([class ,brush]) (code () ,(? string? texts) ...))
         `(pre ([class ,brush]) ,(? string? texts) ...))
     (match brush
       [(pregexp "\\s*brush:\\s*(.+?)\\s*$" (list _ lang))
        `(div ([class ,(str "brush: " lang)])
              ,@(pygmentize (apply string-append texts) lang
                            #:python-executable python-executable
                            #:line-numbers? line-numbers?
                            #:css-class css-class))]
       [_ `(pre ,@texts)])]
    [x x])))

（这里pygmentize是其他Frog源代码中定义的函数；它是将Pygments作为单独的进程运行并对其之间进行管道pygmentize的包装器。但是您可以替代使用Pygments或任何其他语法突出显示器的另一种方法。对于您来说，这是N / A关于match问题。我只是提到它，以免分散注意力，成为另一个嵌入的问题。:)）