扫描整数并在NASM中打印间隔（1，整数）

Question

我正在尝试从Linux Ubuntu 16.04 x64学习汇编语言。 现在，我有以下问题：-扫描整数n并打印从1到n的数字。

对于n = 5，我应该有1 2 3 4 5 。 我试图用scanf和printf来做，但是输入数字后，它退出了。

代码是：

;nasm -felf64 code.asm && gcc code.o && ./a.out

SECTION .data
    message1: db "Enter the number: ",0
    message1Len: equ $-message1
    message2: db "The numbers are:", 0
    formatin: db "%d",0
    formatout: db "%d",10,0 ; newline, nul
    integer: times 4 db 0 ; 32-bits integer = 4 bytes

SECTION .text
    global main
    extern scanf
    extern printf

main:

    mov eax, 4
    mov ebx, 1
    mov ecx, message1
    mov edx, message1Len
    int 80h

    mov rdi, formatin
    mov rsi, integer
    mov al, 0
    call scanf
    int 80h

    mov rax, integer
    loop:
        push rax
        push formatout
        call printf
        add esp, 8
        dec rax
    jnz loop

    mov rax,0

ret

我知道在此循环中我将获得逆输出（5 4 3 2 1 0），但我不知道如何设置条件。

我正在使用的命令如下：

nasm -felf64 code.asm && gcc code.o && ./a.out

您能帮我找出我要去哪里的地方吗？

Answer 1

有几个问题：
1. printf的参数，如注释中所述。 在x86-64中，前几个参数在寄存器中传递。
2. printf不会保留eax的值。
3.堆栈未对齐。
4.使用rbx而不保存调用方的值。
5.正在加载integer的地址而不是其值。
6.由于printf是一个varargs函数，因此在调用之前需要将eax设置为0。
7.调用scanf之后int 80h虚假int 80h 。

我将重复整个功能，以显示上下文中的必要更改。

main:
    push rbx           ; This fixes problems 3 and 4.

    mov eax, 4
    mov ebx, 1
    mov ecx, message1
    mov edx, message1Len
    int 80h

    mov rdi, formatin
    mov rsi, integer
    mov al, 0
    call scanf

    mov ebx, [integer] ; fix problems 2 and 5
    loop:
        mov rdi, formatout   ; fix problem 1
        mov esi, ebx
        xor eax, eax   ; fix problem 6
        call printf
        dec ebx
    jnz loop

    pop rbx            ; restore caller's value
    mov rax,0

ret

PS要使其向上而不是向下计数，请更改循环，如下所示：

    mov ebx, 1
    loop:
        <call printf>
        inc ebx
        cmp ebx, [integer]
    jle loop

Answer 2

您正在使用x86-64 System V调用约定正确调用scanf 。 它把返回值留在eax 。 成功转换一个操作数（ %d ）后，它以eax = 1返回。

... correct setup for scanf, including zeroing AL.

call scanf    ; correct
int 80h       ; insane: system call with eax = scanf return value

然后运行int 80h ，它使用eax=1作为代码来确定哪个系统调用，从而进行32位的legacy-ABI系统调用。 （请参阅如果以64位代码使用32位int 0x80 Linux ABI会发生什么？ ）。

eax=1 / int 80h在Linux上是sys_exit 。 （ unistd_32.h __NR_exit = 1）。 使用调试器； 那会告诉你哪个指令使程序退出。

您的标题（在我更正之前）说您遇到了段错误，但是我在x86-64台式机上进行了测试，事实并非如此。 使用int 80h退出系统调用可以干净地退出。 （但是在执行段错误的代码中，请使用调试器来找出哪条指令。） strace使用unistd_64.h而不是32位unistd_32.h的64位syscall调用编号， 在64位进程中错误地解码了int 0x80系统调用。 unistd_32.h电话号码。

---

您的代码即将开始工作：您将int 0x80 32位ABI正确地用于sys_write ，并且仅将其传递给32位args。 （指针args适合32位，因为在x86-64上的默认代码模型中，始终将静态代码/数据始终放置在虚拟地址空间的低2GiB中。正是由于这个原因，因此您可以使用诸如mov edi, formatin类的紧凑指令将地址放入寄存器，或将它们用作立即数或rel32带符号位移。）

太太，我认为您这样做是出于错误的原因。 正如@prl所指出的，您忘记了保持16字节的堆栈对齐。

同样，将系统调用与C stdio函数混合通常也不是一个好主意。 Stdio使用内部缓冲区而不是总是在每次函数调用时都进行系统调用，因此事情可能会出现混乱，或者当stdin缓冲区中已经有数据时， read可能会等待用户输入。

---

您的循环也会以多种方式中断。 您似乎正在尝试使用32位调用约定（堆栈上的args）调用printf 。

即使在32位代码中，这也是无效的，因为printf的返回值位于eax 。 因此您的循环是无限的，因为printf返回打印的字符数。 这至少是%d\\n格式字符串中的两个，因此dec rax / jnz将始终跳转。

在x86-64 SysV ABI中，如果未在XMM寄存器中传递任何FP args，则在调用printf （使用xor eax,eax ）之前需要将al设置为零。 您还必须在rdi ， rsi ，...中传递args，就像scanf一样。

在推入两个8字节的值后add rsp, 8您还add rsp, 8 ，因此堆栈会永远增长。 （但是您永远不会返回，因此最终的段错误将在堆栈溢出时出现，而不是在尝试使用rsp不指向返回地址返回时出现）。

---

确定您要制作32位还是64位代码，并且仅从示例中复制/粘贴您所针对的模式和操作系统 。 （但是请注意，尽管64位代码可以并且经常确实使用大多数32位寄存器。）

另请参阅在64位系统上组装32位二进制文​​件（GNU工具链） （确实包括带有方便的asm-link脚本的NASM部分，该脚本将汇编并链接为静态二进制文件）。 但是由于您正在编写main而不是_start并正在使用libc函数，因此应该只与gcc -m32链接（如果您决定使用32位代码，而不是用64位函数替换程序的32位部分调用和系统调用约定）。

请参阅i386和x86-64上的UNIX＆Linux系统调用的调用约定是什么 。