Haskell中的无限列表

Question

我正在尝试定义一个函数，该函数在我的简单语法中创建所有可能单词的无限列表。 但是当我输入head (generate [] []) ，ghci会冻结，尽管head (generate' [] [])可以正常工作（但是我仍然想要一个无限列表）。 有什么问题？

data Start = Start deriving(Show)
data MyExpr = MyExprStart Start | MyExpr1 MyExpr | MyExpr2 MyExpr deriving(Show)

generate :: [MyExpr] -> [MyExpr] -> [MyExpr]
generate [] []         = generate [MyExprStart Start] []
generate current prev  = generate (concatMap nextExprs current) (prev ++ current)

generate' :: [MyExpr] -> [MyExpr] -> [MyExpr]
generate' [] []         = generate' [MyExprStart Start] []
generate' current prev  =
  if (length current + length prev) < 5 then
    generate' (concatMap nextExprs current) (prev ++ current)
  else prev ++ current

nextExprs :: MyExpr -> [MyExpr]
nextExprs expr = [MyExpr1 expr, MyExpr2 expr]

UPD：谢谢，我明白了。 我想我应该这样定义我的功能：

generate :: [MyExpr] -> [MyExpr]
generate []         = generate [MyExprStart Start]
generate current    = current ++ generate (concatMap nextExprs current)

Answer 1

generate函数冻结，因为它对无限递归进行编码。 看：它的每种情况都只是调用函数本身。 当它实际返回的不是调用自身的内容时，没有条件。 因此，当您尝试运行它时，它只会一直调用它自己。

另一方面，当两个输入列表的总长度超过5时， generate'函数将立即退出。这样就可以返回结果。

为了使此函数在完全评估之前开始返回数据（它永远做不到），您需要首先返回非递归用例，然后通过递归调用generate来将递归用例附加到它们上：

generate = (MyExprStart Start) : [recur e | e <- generate, recur <- [MyExpr1, MyExpr2]]

GHCI：

> head generate
MyExprStart Start
> take 10 generate
[MyExprStart Start, MyExpr1 (MyExprStart Start),
 MyExpr2 (MyExprStart Start), MyExpr1 (MyExpr1 (MyExprStart Start)),
 MyExpr2 (MyExpr1 (MyExprStart Start)),
 MyExpr1 (MyExpr2 (MyExprStart Start)),
 MyExpr2 (MyExpr2 (MyExprStart Start)),
 MyExpr1 (MyExpr1 (MyExpr1 (MyExprStart Start))), 
 MyExpr2 (MyExpr1 (MyExpr1 (MyExprStart Start))),
 MyExpr1 (MyExpr2 (MyExpr1 (MyExprStart Start)))]

注意：列表理解中的生成器顺序很重要。 如果交换它们，执行将永远不会到达MyExpr2 ，因为它将需要首先耗尽generate列表，并且该列表是无限的。

Answer 2

generate :: [MyExpr] -> [MyExpr] -> [MyExpr]
generate ... = generate ...
generate ... = generate ...

这种形式的任何定义都将在产生任何输出之前始终调用自身。 这种归纳结构只有在至少在某个点上在递归之前返回输出的某些部分（例如发出输出列表的第一个元素）时才能定义。

generate' :: [MyExpr] -> [MyExpr] -> [MyExpr]
generate' [] []         = generate' [MyExprStart Start] []
generate' current prev  =
  if (length current + length prev) < 5 then
    generate' (concatMap nextExprs current) (prev ++ current)
  else prev ++ current

相比之下，在generate'中else分支不会递归，因此它将产生输出。 即使我们有类似的事情

else someNonEmptyList ++ generate' ...

这将起作用，因为将产生前几个列表元素。

此外，请记住，生成将可能的无限列表与++合并的所有可能的表达式不是一个好主意。 确实，如果xs是无限的，则xs ++ ys等于xs ，因为ys在有限的时间内永远不会达到。 当xs和ys无限时，您可能希望公平地交织它们。

一个类似的问题使用了omega monad来实现完整的枚举。