嵌套的Foreach列表NetLogo

Question

你好

在Netlogo v.6中，我试图计算对等方协作行为的时间加权度量。 关键是，我无法弄清楚如何在NetLogo中执行嵌套的foreach。

我目前的做法：

1. 设置列表：信誉_对等
2. 设置一个列表：变量1（行为）和变量2（时间刻度）的信誉列表
3. 每次遇到时，都将信誉清单添加到信誉清单，使信誉清单成为列表清单
4. 计算加权信誉：
   • 将信誉列表中每个列表的项目2，即相遇的时间间隔
   • 并将其除以当前时间刻度。
   • 这给出了一个分数：相遇的滴答声/总时间滴答声
   • 设置列表信誉
   • 要权衡信誉，请将时间分数乘以信誉变量的第一项（行为变量）
5. 然后，我想了解信誉信誉，方法是从信誉信誉加权中获取所有值并将其相加。

我搞砸了foreach函数，但似乎无法弄清楚。 如何在Netlogo中编码这种方法？

我当前的代码是（自己设置信誉信誉以对其进行测试）：

to calculate_reputation
    set reputation_peer [[8 4][9 2][10 3][11 2][14 1]]
    if ticks > 0 [
      foreach reputation_peer [x -> set reputation_peer_list list (item 0 x) ((item 1 x) / ticks )
      set reputation_peer_list_2 lput reputation_peer_list reputation_peer_list_2]
      foreach reputation_peer_list_2 [x -> set reputation_peer_list_list (list (item 0 x * item 1 x))]
      foreach reputation_peer_list_list [x -> set reputation_peer_current reputation_peer_current + x] 
    ]
end

我真的不知道我是否做对了，但是主要来说，这段代码在处理所有list_list事情时看起来非常庞大。 我猜这可能会简单得多。

如果你们有一些提示，将极大地帮助我。

Answer 1

我不确定您对最终输出的期望是100％不确定的，但是也许这是您所需要的？

to calc-rep-2
  set reputation_peer [[8 4][9 2][10 3][11 2][14 1]]
  let weighted_rep_list []

  if ticks > 0 [
    foreach reputation_peer [ x ->
      ; Pull out the values from reputation_peer for ease of use
      let encounter_behavior item 0 x
      let encounter_time item 1 x

      ; Calculate the time fraction for the current item
      let time_fraction encounter_time / ticks

      ; Calculate the weighted reputations
      let weighted_rep encounter_behavior * time_fraction

      ; Add the weighted rep to the list of weighted reps
      set weighted_rep_list lput weighted_rep weighted_rep_list
    ]

    ; Now, weighted_rep_list is a list of weighted reputations
    print weighted_rep_list

    ; Get the sum of the list
    print sum weighted_rep_list
  ]  

  tick
end