如何在SAS报告Webout文件中打印选中和未选中的复选框

Question

我有一个名为Proposal的表，其中有一个列名value_cd。 此列具有一些复选框的值，这些复选框将在我的Webout报告中选中。 我想选中所有相关值在此列中的复选框。

table:Proposal 
  value_cd

   New_par
   Rev_par

这是我的代码

data _null_;
 put numberOfObservationes=;
 set work.Proposal nobs=numberOfObservationes;
 file _webout;
    if value_cd eq "New_par" then put '<input type=checkbox disabled checked /> <label>New Parameter</label> <br /> <hr /> ';
          else put '<input type=checkbox disabled /> <label>New Parameter</label> <br /> <hr /> ';
    if value_cd eq "Rev_par" then put '<input type=checkbox disabled checked /> <label>Revised Parameter</label> <br /> <hr /> ';
          else put '<input type=checkbox disabled /> <label>Revised Parameter</label> <br /> <hr /> ';
    if value_cd eq "New_pro" then put '<input type=checkbox disabled checked /> <label>New Process</label> <br /> <hr /> ';
          else put '<input type=checkbox disabled /> <label>New Process</label> <br /> <hr /> ';
run;

我只想在报告中打印一次复选框，并且应该根据表的value_cd列的值对其进行检查或取消选中，但是如果条件中的值不相等，则运行else语句，并且代码正在打印复选框直到计数value_cd。

我如何仅基于value_cd的复选框打印一次。

我要这个

  checkbox checked New Parameter        *if-statement;
  checkbox checked Revised Parameter    *if-statement;
  checkbox New Process                  *else-statement;

上面的代码在下面打印输出

  checkbox checked New Parameter  *if-statement;
  checkbox Revised Parameter      *else-statement;
  checkbox New Process            *else-statement;
  checkbox New Parameter          *else-statement;
  checkbox checked Revised Parameter   *if-statement;
  checkbox New Process            *else-statement;

Answer 1

逐行发生的6个复选框：

row-1: logic-1-output logic-2-output logic-3-output
row-2: logic-1-output logic-2-output logic-3-output

所需的是3个复选框：

row-1: track-logic-1-for-true track-logic-2-for-true track-logic-3-for-true
row-2: track-logic-1-for-true track-logic-2-for-true track-logic-3-for-true
last-row: output-based-on-tracked-logics

这是一种方法

跟踪发生在所有行上的value_cd状态，然后执行输出。

data _null_;
 put numberOfObservationes=;
 set work.Proposal nobs=numberOfObservationes end=last_row;

 array boxes[3] _temporary_; * 1st slot is for New_par, 2nd for Rev_par, etc..;

 * track for true using OR;
 boxes[1] = boxes[1] or (value_cd eq "New_par");
 boxes[2] = boxes[2] or (value_cd eq "Rev_par");
 boxes[3] = boxes[3] or (value_cd eq "New_pro");

 if last_row then do;
    if boxes[1]
      then checked_attribute='checked'; 
      else checked_attribute='';

    put '<input type=checkbox disabled ' checked_attribute '/> <label>New Parameter</label> <br /> <hr /> ';

    if boxes[2]
      then checked_attribute='checked'; 
      else checked_attribute='';

    put '<input type=checkbox disabled ' checked_attribute '/> <label>Revised Parameter</label> <br /> <hr /> ';

    if boxes[3]
      then checked_attribute='checked'; 
      else checked_attribute='';

    put '<input type=checkbox disabled ' checked_attribute '/> <label>New Process</label> <br /> <hr /> ';
  end;
run;

注意：上面的代码实质上是将value_cd数据从一列透视到单行。

在DATA Step中，变量值通常在隐式循环的顶部重置为丢失（在这种情况下，当您从第1行转到第2行时）。 为了逐行跟踪条件，隐式循环不应重置变量。

有两种避免重置的方法：

• 使用RETAIN变量
• 使用_temporary_数组
• 切勿让隐式循环发生多次：
  • 在显式编码的do while或do until循环中使用SET 。
• 将所有状态信息放在一行中（即，透视）