如何在Oracle中将动态SQL执行到游标中？

Question

我在存储过程中将动态sql语句执行到sys_refcursor中时遇到问题。 我查看了文档，并认为我可以正确构建过程，但是我仍然不知道为什么会发生错误。 请看下面我创建的内容：

CREATE TABLE REKOM_CROSS_PROM (
      LINIA_PROD VARCHAR2(20), 
      ID_REKOM_OFERTA VARCHAR2(20),
      PRICE NUMBER,
      MAX_PRICE NUMBER
    );
/

CREATE OR REPLACE TYPE prodType AS OBJECT (
p_line VARCHAR2(20)
,p_price NUMBER
);
/

CREATE OR REPLACE TYPE prodTypeList IS TABLE OF prodType;
/

CREATE OR REPLACE PROCEDURE my_proc (prodLines IN prodTypeList ,rekom OUT SYS_REFCURSOR)
IS
v_pLine VARCHAR2(20);
v_query VARCHAR2(4000);
BEGIN
  v_query := 'SELECT ID_REKOM_OFERTA FROM REKOM_CROSS_PROM WHERE 
LINIA_PROD=NULL';
FOR i IN 1 .. prodLines.COUNT
    LOOP
        v_pLine := prodLines(i).p_line;
        v_query := v_query || ' UNION ALL SELECT ID_REKOM_OFERTA FROM 
                    REKOM_CROSS_PROM WHERE LINIA_PROD=''' || v_pLine || '''';
    END LOOP;
OPEN rekom FOR v_query;
END my_proc;
/

当我要调用该过程时，会发生错误。

set serveroutput on
    declare
    type1 prodTypeList := prodTypeList(prodType('test1',1), prodType('test2', 20));
    rc SYS_REFCURSOR;
    row varchar2(200);
BEGIN
    MY_PROC(type1, rc);
    fetch rc into row;
    while (rc%found) loop
    dbms_output.put_line(row);
end loop;
close rc;
end;

我收到消息：

ORA-20000：ORU-10027：缓冲区溢出，限制为1000000字节

*原因：存储过程'raise_application_error'被调用，导致生成此错误。

*操作：如错误消息中所述纠正问题，或与应用程序管理员或DBA联系以获取更多信息。

某人可以帮助我解决问题吗？

Answer 1

您有一个无限循环。 这意味着您将永远调用dbms_output.put_line或直到它耗尽缓冲区空间并引发该异常为止。

BEGIN
  MY_PROC(type1, rc);
  -- fetch first row from result set
  fetch rc into row;
  -- check if last fetch found something - always true
  while (rc%found) loop
    dbms_output.put_line(row);
  end loop;
  close rc;
end;

每次循环时，您都要检查第一次提取的结果，该结果保持为真（假设有任何数据）。 您需要每次循环获取一次：

BEGIN
  MY_PROC(type1, rc);
  -- fetch first row from result set
  fetch rc into row;
  -- check if last fetch found something
  while (rc%found) loop
    dbms_output.put_line(row);
    -- fetch next row from result set
    fetch rc into row;
  end loop;
  close rc;
end;

也许更常见的是，仅在循环内部获取，并在找不到任何内容时停止，使用%notfound而不是%found ：

BEGIN
  MY_PROC(type1, rc);
  loop
    -- fetch row from result set
    fetch rc into row;
    -- check if last fetch found something
    exit when rc%notfound;
    dbms_output.put_line(row);
  end loop;
  close rc;
end;

---

与您当前的问题无关，但是谓词WHERE LINIA_PROD=NULL永远不会为真； null不等于（或不等于）其他任何值。 您需要改用WHERE LINIA_PROD IS NULL 。