使用msiexec卸载应用程序时，GUID可以替代吗？

Question

当前，当我们运行包含msiexec的卸载脚本时，我们正在使用GUID来识别应用程序。 我遇到的问题是，每次安装最新版本的应用程序时，GUID都会更改，因此我想知道是否可以通过其他方式识别使用msiexec运行的应用程序？

Answer 1

首先： 正常情况下，产品GUID会针对应用程序的新版本进行更改 ，尽管也可以在不更改产品GUID的情况下升级某些应用程序（称为次要升级 -与更改产品GUID的主要升级相反） ）。 在相同产品的不同版本之间趋于保持稳定的是UpgradeCode （它定义了一系列相关产品）。 ProductCode唯一标识产品（在特定版本中）。

这里列出了一些卸载选项： 在不使用msiexec的情况下从命令行卸载MSI文件 。

我想您可以按照section 3说明使用MSI文件名，或者如果产品名称保持稳定，则可以与自动化一起使用它来查找正确的产品GUID来卸载有问题的产品。 我将稍后进行测试并更新答案。

---

更新 ：一个用于按“产品名称”卸载产品的示例VBScript（假定它在各个发行版中保持不变，通常这样做，但是不能保证-它取决于产品）。

在“添加/删除程序”中找到产品名称-或使用此答案底部的微型VBScript链接，以导出带有所有已安装软件包信息的小文本文件。

' On Error Resume Next ' Used to suppress errors

Const msiUILevelNone = 2
Const msiUILevelFull = 5
Const msiInstallStateAbsent = 2

Set installer = CreateObject("WindowsInstaller.Installer")
Set products = installer.ProductsEx("", "", 7)
installer.UILevel = msiUILevelFull  ' Running with full GUI (if available in MSI)
' installer.UILevel = msiUILevelNone ' Will run uninstall silently, run script with admin rights

' Get the product name from the user
productname = InputBox("Please enter the product name for the MSI package you wish to uninstall:")
If productname = vbCancel Or Trim(productname) = "" Then
   WScript.Quit(0)
End If    

' Iterate over all MSI packages on the box
For Each product In products

   currentproduct = product.InstallProperty("ProductName")

   If LCase(currentproduct) = LCase(productname) Then

      installer.ConfigureProduct product.productcode, 0, 2 ' msiInstallStateAbsent
      MsgBox "Ran uninstall for: " & currentproduct
      Exit For ' End product iteration, assuming only one product needed uninstall

   End If 

Next

Set installer = Nothing

MsgBox "Finished."

---

更新 ：您可以使用VBScript创建自己的产品代码和产品名称的快速列表，如该答案底部所述： 如何找到已安装的MSI设置的产品GUID？ 。 我认为，这个特定的VBScript非常简单。

Answer 2

人们在这种情况下解决各种ProductCode值的通常方法是从更稳定的UpgradeCode开始。

给定UpgradeCode，您可以使用MsiEnumRelatedProducts（或脚本或MSI互操作等效项）返回ProductCode。 像这样的代码通常不需要更改。

我很确定PowerShell应该能够做到这一点。

Answer 3

您知道什么不会改变，还是会改变但可以轻松跟踪？

• 说产品代码已更改，但升级代码未更改。 您可以按照PhilDW的建议，使用MsiEnumRelatedProducts或Installer.Related或等效方法从升级代码中检索产品代码。

• 说名字不一样。 您可以按照Stein的建议以产品名称查找产品代码，从MsiEnumProductsEx或Installer.ProductsEx或等效名称开始。

• 假设您将安装的.msi的本地副本缓存在不变的位置，或者在脚本中轻松找到了该副本。 您可以按照4c74356b41的建议在命令行中使用该路径访问msiexec。 （请注意， msiexec / x接受程序包路径或产品代码。）

• 假设您不喜欢这些选项中的任何一个。 也许您可以在HKEY_LOCAL_MACHINE \\ Software \\ YourCompany \\ YourProduct中添加一个注册表值，将字符串值ProductCode设置为[ProductCode] 。 然后，您可以使用reg query HKLM\\Software\\YourCompany\\YourProduct /v ProductCode或同等功能（对不起，我对PowerShell reg query HKLM\\Software\\YourCompany\\YourProduct /v ProductCode ）来获取当前产品代码。 （当然，至少要考虑32位和64位路径。）