使用perl检查嵌套目录结构是否为空

Question

我的要求是检查嵌套目录结构是否具有任何二进制文件。

目录结构如下所示：

DIR-A
    |
    |--DIR-X
    |       |
    |       |--DIR-X1
    |       |--DIR-X2
    |
    |--DIR-Y
    |       |
    |       |--DIR-Y1
    |       |--DIR-Y2
    |       |--DIR-Y3
    |
    |--DIR-Z
    |       |
    |       |--DIR-Z1
    |       |--DIR-Z2
    |       |--DIR-Z3

在任何时间点，级别1或级别2上都可以有更多目录，即级别1可以有更多目录，例如DIR-P, DIR-Q等，而级别1可以有DIR-X3 or DIR-Y4 2级。

我已经编写了一个示例代码，但是如果找到DIR-X1它将退出，理想情况下，如果目录中有二进制文件，则应退出。

#!/usr/bin/perl

my $someDir = "/path/of/DIR-A";
my @files = ();
my $file;
my $i=0;

opendir(DIR, "$someDir") or die "Cant open $someDir: $!\n";
    @files = readdir(DIR);
    foreach $file(@files) 
    {
          unless ($file =~ /^[.][.]?\z/) 
        {
            print "$i : $file \n";              
            $i++;
            last;
            }
        }

    if ($i != 0) 
    {
        print "The directory contains files! \n";
        exit 1;      
    } 
    else 
    {
        print "This DIR-A is Empty! \n";
        exit 0;
    }

closedir(DIR);

请建议我达到预期的解决方案，如下所示：

read DIR-A
print SUCCESS, if none of the nested directories have a binary file.
print ERROR, if at least one of the nested directories has a binary file.

谢谢！

Answer 1

使用File::Find::Rule

#!/usr/bin/env perl
use strict;
use warnings;

use File::Find::Rule;

my $someDir = "/path/of/DIR-A";

my @files = File::Find::Rule->file()
                            ->name('*.bin')
                            ->in($someDir);

这将使您具有扩展名“ .bin”的所有文件。

如果您需要执行每个文件测试以检查它们是否是“二进制”，则可以在@files列表上使用grep 。

my @files = grep {-B} File::Find::Rule->file()
                                      ->in($someDir);

print "Binary files found\n" if @files;

也：

• use strict; use warnings; 。 很好。
• 代码格式化确实是一件好事。 perltidy -pbp使其变得容易。

Answer 2

我不清楚要测试的二进制文件是什么。 我假设遍历目录结构中找到的任何文件都是二进制文件。 使用File::Find ，这是一个核心模块：

use File::Find;

my $error = 0;
find(\&wanted, @ARGV);

if( $error ) {
  print "ERROR, $error files found\n";
}
else {
  print "SUCCESS\n";
}

sub wanted {
  if( -f $_ ) {
    $error++;
  }
}

您可以将任何测试添加到wanted功能。 find函数将调用为还通过的目录列表中找到的每个文件提供的函数，该函数将按深度优先的搜索顺序进行递归遍历（与find命令一样）。@ @ARGV传递它可以调用具有所需目录列表的脚本（也许使用像DIR-*这样的shell扩展）。

测试功能将获得在$_中遍历的文件名，而当前的工作目录将设置为包含该文件的目录。

Answer 3

您可以使用以下脚本查找二进制文件是否存在或递归。

#! /usr/bin/env perl
use warnings;
use strict;
use File::Find;

my $path="/path/of/DIR-A";

sub find_binary {
    my $file = $File::Find::name;

    if (-B $file && ! -d $file) {
        print "ERROR: At least one of the nested directories has a binary file : $file\n";
        exit;
    }
}

find(\&find_binary,$path);
print("SUCCESS: None of the nested directories have a binary file. \n");

Answer 4

使用（警告：我的）模块File::Globstar ：

use v5.10;
use File::Globstar qw(globstar);

my $dir = $ARGV[0] // '.';
say join "\n", grep { -B && ! -d } globstar "$dir/**";

如果要在列表中包含文件列表，请分配它而不是打印它：

my @nondirs = grep { -B && ! -d } globstar "$dir/**";

如果您知道文件的扩展名，也可以执行以下操作：

my @nondirs = grep { -B && ! -d } globstar "$dir/**/*.png";

请注意，文件test -B为空文件生成一个真实值，这也许不是您想要的。 在这种情况下，将测试更改为-B && -s && ! -d -B && -s && ! -d