使用xsl文件将xml属性的内容复制到xml元素中

Question

我有xml文件的以下部分

<ns1:Main ns1:IdentifiantMain="token_new" ns1:Operation="Aucune">
          <ns1:elementA>token_old</elementA>
        </ns1:Main>

我想要进行转换以创建新的xml，如下所示：

<ns1:Main ns1:IdentifiantMain="token_new" ns1:Operation="Aucune">
      <ns1:elementB>token_new</elementB>
    </ns1:Main>

其中基本上是旧元素被删除，而新元素“ elementB”则填充了属性“ ns1：IdentifiantMain”的内容

我尝试使用followint xsl文件，但实际上。 它不起作用。

    <?xml version='1.0' encoding='UTF-8'?>
<xsl:stylesheet version="2.0" xmlns="http://xml.rsi.fr/schema" xmlns:xsl="http://www.w3.org/1999/XSL/Transform" xmlns:ns1="http://xml.rsi.fr/schema">
    <xsl:template match="@*|node()">
        <xsl:copy>
            <xsl:apply-templates select="@*|node()" />
        </xsl:copy>
    </xsl:template>

    <xsl:template match="ns1:Main">
    <xsl:copy-of select="."/>
        <ns1:elementB>
            <xsl:value-of select = "@ns1:elementB/ns1:IdentifiantMain"/>
        </ns1:elementB> 
    </xsl:template>
</xsl:stylesheet>

有什么提示吗？

Answer 1

xsl:copy-of是一个深层副本，它将复制ns1:Main元素及其后代。 由于要更改子元素，因此需要使用xs:copy 。

xsl:copy是一个浅表副本，仅复制ns1:Main元素。 如果您还想复制其属性，则可以添加<xsl:copy-of select="@*"/>来显式复制属性，也可以添加<xsl:apply-templates match="@*"/>查找任何匹配的模板，然后点击上面的通用标识模板，这将复制属性。 然后，在ns1:elementB ，选择@ns1:IdentifiantMain的值。 由于您的模板与ns1:Main匹配，因此您的XPath是相对上下文。

<xsl:template match="ns1:Main">
  <xsl:copy>
    <xsl:copy-of select="@*"/>
    <ns1:elementB>
      <xsl:value-of select = "@ns1:IdentifiantMain"/>
    </ns1:elementB> 
  </xsl:copy>
</xsl:template>

或者，不匹配ns1:Main元素，而是匹配要替换的元素ns1:elementA 。 然后，不要复制模板中的该元素，而是构造ns1:elementB ，然后获取ns1:elementA父元素的@ns1:IdentifiantMain 。

<xsl:stylesheet version="2.0" xmlns="http://xml.rsi.fr/schema" xmlns:xsl="http://www.w3.org/1999/XSL/Transform" xmlns:ns1="http://xml.rsi.fr/schema">
    <xsl:template match="@*|node()">
        <xsl:copy>
            <xsl:apply-templates select="@*|node()" />
        </xsl:copy>
    </xsl:template>

    <xsl:template match="ns1:elementA">
        <ns1:elementB>
            <xsl:value-of select="../@ns1:IdentifiantMain"/>
        </ns1:elementB> 
    </xsl:template>
</xsl:stylesheet>