UDF中缺少ParamArray

Question

我试图确定何时在没有提供ParamArray参数的情况下在工作表上使用了使用ParamArray的用户定义函数（UDF）。

我已经尝试过IsEmpty，IsArray，IsError，什么都没有比较，零长度字符串比较等等。

我知道paramarray始终是byVal，而variant数组始终是从零开始的，但是如果它不存在，它怎么是数组？

• 比较数组的第一个元素为Nothing或Not Nothing会引发错误
• IsEmpty报告错误
• IsArray奇怪地报告为True
• IsError报告两个测试和测试均为False（0）

testParams UDF：

Public Function testParams(ByRef ndx As Long, ParamArray tests())
    Select Case ndx
        Case 1
            testParams = CBool(tests(LBound(tests)) Is Nothing)
        Case 2
            testParams = IsEmpty(tests)
        Case 3
            testParams = IsArray(tests)
        Case 4
            testParams = IsError(tests)
        Case 5
            testParams = CBool(tests(LBound(tests)) = vbNullString)
    End Select
End Function

在下面的示例中，我只是将尝试访问ParamArray返回的内容返回到工作表。

如何确定用户是否未在需要它们的真实UDF中提供ParamArray参数？ 我宁愿使用简单的布尔检查还是将测试与是否某事都不做进行对比。

Answer 1

_{TL; DR-如果IsMissing（tests）然后使用...}

NTL和WR：

即使不能将ParamArray与任何已声明的Optional参数（包括ParamArray本身）一起使用，但是如果省略了它，则不会引发任何错误。 可以很容易地说，尽管无法将ParamArray标记为可选，但它始终是可选的 。

^{从： 参数数组（Visual Basic）}
_{参数数组是自动可选的。 它的默认值是参数数组的元素类型的空一维数组。}

用户未提供的ParamArray将是已实例化但未填充或未确定尺寸的变量数组。

它的LBound定义为0（零）， UBound定义为-1（负1）。 这与已声明但未标注尺寸的任何其他变量数组相同。

由于它始终是变量类型参数 ，因此也会通过IsMissing正确报告其存在或不存在。

Public Function testParams(ByRef ndx As Long, ParamArray tests())
    Select Case ndx
        Case 1
            testParams = CBool(tests(LBound(tests)) Is Nothing)
        Case 2
            testParams = IsEmpty(tests)
        Case 3
            testParams = IsArray(tests)
        Case 4
            testParams = IsError(tests)
        Case 5
            testParams = CBool(tests(LBound(tests)) = vbNullString)
        Case 6
            testParams = CBool(UBound(tests) = -1)
        Case 7
            testParams = IsMissing(tests)
    End Select
End Function

测试IsMissing或UBound值是否为-1将确定用户是否提供了paramarray。

Answer 2

数组分配的一个很好的解释是在http://www.cpearson.com/Excel/IsArrayAllocated.aspx

Excert：

下面的函数IsArrayAllocated将准确地返回True或False，指示是否分配了数组。 此函数将同时适用于任意数量的维的静态和动态数组，并且将正确处理具有有效（非错误） LBound值的未分配数组

和功能

Function IsArrayAllocated(Arr() As Variant) As Boolean
    On Error Resume Next
    IsArrayAllocated = IsArray(Arr) And _
        Not IsError(LBound(Arr, 1)) And _
        LBound(Arr, 1) <= UBound(Arr, 1)
End Function

与带有参数数组的Function一起使用

Function MyFunc(ParamArray pa()) As Variant
    Dim v()
    v = pa
    If IsArrayAllocated(v) Then
        'Do stuff with the parameters
    Else
        'There are no parameters...
    End If
End Function