Neo4j-查找从未与其他节点有任何关系的节点

Question

假设我有一个带有这样的节点和关系的示例：

(:Node_A) -[:rel_a]-> (:Node_B) -[:rel_b]-> (:Node_C)

我想找到从未与(:Node_C {label:'A'})有关系的Node_A所有节点。

我试过了：

MATCH (a:Node_A) -[:rel_a]-> (b:Node_B), (c:Node_C {label:'A'})
WHERE NOT (b) -[:rel_b]-> (c)
RETURN a

但是我没有得到预期的结果。

如果我具有这些节点和关系，则不希望返回node_a 。

(node_a:Node_A) -[:rel_a]-> (b1:Node_B),
(node_a:Node_A) -[:rel_a]-> (b2:Node_B),

(b1:Node_B) -[:rel_b]-> (c:Node_C {label:'A'}),
(b1:Node_B) -[:rel_b]-> (c1:Node_C {label:'B'}),

(b2:Node_B) -[:rel_b]-> (c2:Node_C {label:'C'})

如何匹配从未与(:Node_C {label:'A'})没有任何关系的节点？

Answer 1

之所以没有得到预期的结果，是因为存在与给定模式匹配的路径（一个Node_A节点连接到Node_B节点，因此Node_B节点未连接到label:'A'的Node_C节点）。 这是因为，根据示例图的描述，您有2个：Node_B节点连接到您的单个：Node_A节点。 其中一个连接到两个：Node_C节点，其中一个是您要避免的：Node_C节点（在这种情况下，由于您的WHERE子句，带有该：Node_B节点的THAT路径被过滤掉了），并且其他：Node_B节点连接到带有标签'C'的安全：Node_C节点，这是适合您的查询并返回的路径。

您可以通过几种方式获得所需的过滤条件。

一种是在WHERE子句中定义要完全排除的完整模式，然后将：Node_B部分保留在MATCH子句之外：

MATCH (a:Node_A), (c:Node_C {label:'A'})
WHERE NOT (a) -[:rel_a]-> (:Node_B) -[:rel_b]-> (c)
RETURN a

如果您不了解或不关心中间节点或a和c之间a关系，则可以从模式中省略它们：

MATCH (a:Node_A), (c:Node_C {label:'A'})
WHERE NOT (a) --> () --> (c)
RETURN a

您可以使用可变长度关系表示同一件事，其中我们知道c只能相距2跳：

MATCH (a:Node_A), (c:Node_C {label:'A'})
WHERE NOT (a) -[*2]-> (c)
RETURN a

编辑

stdob--正确地指出，对于所有这些方法，我们假设图中存在带有label:'A'的:Node_C节点。 如果不能保证这一点，并且碰巧没有这样的节点，那么这些查询将不会返回任何内容。

如果我们必须处理这种潜在的情况，那么最好将其从MATCH移到WHERE子句中：

MATCH (a:Node_A)
WHERE NOT (a) -[*2]-> (:Node_C {label:'A'})
RETURN a

实际上，在任何情况下这都是一件好事，好像我们有多个这样的节点，而不是只有一个这样的节点，如果将其保留在MATCH子句中，可能会弄乱我们的结果。