XNK数据未填充在我的xslt代码中

Question

这是我的第一个XSLT脚本，对XML或其工作原理一无所知。

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0">      
    <xsl:template match="/*">
        <FMPXMLRESULT xmlns="http://www.filemaker.com/fmpxmlresult">
            <ERRORCODE>0</ERRORCODE><PRODUCT BUILD="" NAME="" VERSION=""/>
            <DATABASE DATEFORMAT="" LAYOUT="" NAME="" RECORDS="" TIMEFORMAT=""/>
            <METADATA>

将XSLT映射到Filemaker的工作原理如下

                <FIELD EMPTYOK="YES" MAXREPEAT="1" NAME="IncID" TYPE="TEXT"/>
            </METADATA>

在下面的某个地方，我需要填充FM数据库。正在填充单个名称，但不填充XML数据。

            <RESULTSET>
                <ROW>
                    <COL>
                        <DATA><xsl:value-of select="IncID"/></DATA>
                    </COL>
                </ROW>
            </RESULTSET>
        </FMPXMLRESULT>
    </xsl:template>
</xsl:stylesheet>

下面是一个简短的XML文档，每次上载时文件名都会更改。 下面没有任何变化。

<dataSet xmlns="http://www.ibm.com/xmlns/prod/cognos/dataSet/201006">
    <dataTable>
        <id>IncidentHeader</id>
        <row>
            <IncID>286996</IncID>
            <IncNumber>ZA-RDF-0190</IncNumber>
        </row>
    </dataTable>
    <dataTable>
        <id>IncidentRequests</id>
        <row>
            <IncID>286996</IncID>
            <ResID>2412136</ResID>
            <ReqID>7820453</ReqID>
            <RootReqFlag>Yes</RootReqFlag>
        </row>
        <row>
            <IncID>286996</IncID>
            <ResID>2258222</ResID>
            <ReqID>7820454</ReqID>
            <RootReqFlag>Yes</RootReqFlag>
        </row>
    </dataTable>
</dataSet>

Answer 1

XML具有缺省名称空间xmlns="http://www.ibm.com/xmlns/prod/cognos/dataSet/201006" ，所有元素都与该名称空间相关联。 该名称空间需要在XSLT中进行映射，并且应该使用名称空间前缀来访问元素。 此处ns0用作前缀。

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform" 
    xmlns:ns0="http://www.ibm.com/xmlns/prod/cognos/dataSet/201006">

所述XSLT正在用文档根模板匹配/访问任何元件因此，当，需要指定该元素的完整的XPath。 根据要访问所有IncID元素还是要访问特定的IncID元素，XPath会有所不同。

如果输出需要所有IncID元素的值（尽管值相同，但XPath会有所不同），则可能需要<xsl:for-each>循环来获取输出。

<RESULTSET>
    <ROW>
        <xsl:for-each select="ns0:dataSet/ns0:dataTable/ns0:row">
            <COL>
                <DATA><xsl:value-of select="ns0:IncID" /></DATA>
            </COL>
        </xsl:for-each>
    </ROW>
</RESULTSET>

在这种情况下的输出将是

<RESULTSET>
    <ROW>
        <COL>
            <DATA>286996</DATA>
        </COL>
        <COL>
            <DATA>286996</DATA>
        </COL>
        <COL>
            <DATA>286996</DATA>
        </COL>
    </ROW>
</RESULTSET>

如果仅要提取首次出现的IncID的值，则可以使用

<xsl:value-of select="//ns0:row[1]/ns0:IncID" />

要么

<xsl:value-of select="//ns0:IncID[1]" />

在这种情况下的输出看起来像

<RESULTSET>
    <ROW>
        <COL>
            <DATA>286996</DATA>
        </COL>
    </ROW>
</RESULTSET>

Answer 2

我假设您要将所有数据导入到单个FileMaker表中。 在这种情况下，您必须对源进行一些解析，因为您似乎在源中有2个表IncidentHeader和IncidentRequests，每个表都包含在相同的“ dataTable”元素中。 但是，它们确实共享关键字段IncID，然后可以使用该字段将IncNumber提取到IncidentRequest数据中。

我认为，这应该可以解决问题。

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0">
<xsl:template match="/*">
        <FMPXMLRESULT xmlns="http://www.filemaker.com/fmpxmlresult" xmlns:c="http://www.ibm.com/xmlns/prod/cognos/dataSet/201006">
            <ERRORCODE>0</ERRORCODE>
            <PRODUCT BUILD="" NAME="" VERSION=""/>
            <DATABASE DATEFORMAT="M/d/yyyy" LAYOUT="" NAME="" RECORDS="{count(c:dataTable[c:id='IncidentRequests']/c:row)}" TIMEFORMAT="h:mm:ss a"/>
            <METADATA>
                <FIELD>
                    <xsl:attribute name="EMPTYOK">YES</xsl:attribute>
                    <xsl:attribute name="MAXREPEAT">1</xsl:attribute>
                    <xsl:attribute name="NAME">IncNumber</xsl:attribute>
                    <xsl:attribute name="TYPE">TEXT</xsl:attribute>
                </FIELD>
                <xsl:for-each select="c:dataTable[c:id='IncidentRequests']/c:row[position()=1]/*">
                    <FIELD>
                        <xsl:attribute name="EMPTYOK">YES</xsl:attribute>
                        <xsl:attribute name="MAXREPEAT">1</xsl:attribute>
                        <xsl:attribute name="NAME"><xsl:value-of select="name()"/></xsl:attribute>
                        <xsl:attribute name="TYPE">TEXT</xsl:attribute>
                    </FIELD>
                </xsl:for-each>
            </METADATA>
            <RESULTSET>
                <xsl:attribute name="FOUND"><xsl:value-of select="count(c:dataTable[c:id='IncidentRequests']/c:row)"/></xsl:attribute>
                <xsl:for-each select="c:dataTable[c:id='IncidentRequests']/c:row">
                    <xsl:variable name="incid">
                        <xsl:value-of select="c:IncID"/>
                    </xsl:variable>
                    <ROW>
                        <xsl:attribute name="MODID">0</xsl:attribute>
                        <xsl:attribute name="RECORDID">0</xsl:attribute>
                        <COL>
                            <DATA>
                                <xsl:value-of select="//c:dataTable[c:id='IncidentHeader']/c:row[c:IncID=$incid]/c:IncNumber"/>
                            </DATA>
                        </COL>  
                        <xsl:for-each select="child::*">
                            <COL>
                                <DATA>
                                    <xsl:value-of select="."/>
                                </DATA>
                            </COL>
                        </xsl:for-each>
                    </ROW>
                </xsl:for-each>
            </RESULTSET>
        </FMPXMLRESULT>
    </xsl:template>
</xsl:stylesheet>