使用Windows ren命令删除！ 从文件名

Question

我有一堆文件格式如下

filename-!#.ext

其中＃是一个递增的数字，以防止碰撞。 我想删除！ 从文件名中读取为

filename-#.ext

似乎我可以使用ren命令和通配符执行此操作，但很难让它工作。 我试过这个：

ren *!?.ext *?.ext

我的想法是*应该匹配文件名 - 部分，然后！，然后是？ 对于数字。 但是，生成的文件名为：

filename-!#.ext.ext

我无法弄明白为什么。

文件名部分可以是动态的，但不包含任何！。 有任何想法吗？

Answer 1

我认为rename选择文件并不是一个好主意，而是使用for -loop执行它，然后为每个文件执行重命名：

for %%F in (*!*) do (
    set "nxF=%%~nxF"
    call ren "%%nxF%%" "%%nxF:!=%%"
)

你真的必须在这里使用call而不是delayedExpansion ，因为delayedExpansion会破坏rename-arguments（因为它们包含! ）

Answer 2

我认为你将不得不求助于一个小的批处理文件：

@echo off
    setlocal
    for %%a in (*!*.ext) do call :remove "%%~a"
    goto :eof

:remove
    set "FROM=%~1"
    set "TO=%FROM:!=%"
    ren "%FROM%" "%TO%"
    goto :eof

上面会-包含一个感叹号和扩展名的文件ext -调用remove功能。 这将使用原始名称（ FROM ）并通过使用%var:find=replace%语法来删除任何感叹号（用空字符串替换它）来确定新名称（ TO ）。

笔记

• 您不能对%%a或%0类型变量使用find / replace，因此必须先将其分配给命名变量。

• 我最初尝试使用for语句进行“内联”（例如， for ... (结束) ），但为此，您必须启用延迟扩展（因为您需要在循环中访问命名变量）。 但是，延迟扩展使用! （而不是% ）引用变量，这阻碍了! 我们试图删除。 可能有一种方法可以做到这一点，但我还没有找到它。 除非你有成千上万的文件，否则使用call会稍慢，但不会显着。

• 你真的不需要创建TO （你可以在ren命令行上执行替换），但为了清楚起见我使用了它。

• 这适用于带有感叹号的所有文件：它不会在数字后检查位。

Answer 3

根据您提供的信息，只是为了提供一些不同的东西，您可以让延迟扩展为您完成工作（因为它会为您删除不需要的感叹号） 。

@For %%A In ("*-!?.ext") Do @Set "_=%%A" & SetLocal EnableDelayedExpansion & Ren "!_!" "%%A" & EndLocal

---

您也可以使用嵌套for循环来完成它：

@For %%A In ("*-!?.ext") Do @For /F "Tokens=1*Delims=!" %%B In ("%%A") Do @Ren "%%A" "%%B%%C"

...并从命令提示符：

For %A In ("*-!?.ext") Do @For /F "Tokens=1*Delims=!" %B In ("%A") Do @Ren "%A" "%B%C"