尝试在足球数据库中获取最大连续胜利数

Question

因此，我试图从我的足球数据库中获得最长的连胜纪录。 我知道在堆栈溢出方面有很多类似的问题，但是大多数解决方案最终只是增加每个团队的总胜利，这不是我想要获得的。

我的目标是获得球队有史以来最长的连胜纪录。 本质上，如果team1玩了10场比赛，并且在这10场比赛中连续赢了6次，然后输了1场，又连续赢了3场，那么连续的获胜命令应返回team1的最大连胜数为6。

我拥有的代码虽然显示了每个玩家的获胜总数，但这并不是我想要获得的。

MATCH (T1:Team)-[m:Match]-(:Team)
with T1, m
ORDER BY m.round ASC
WITH T1,
REDUCE(initial = {wins: 0, max_wins: 0}, matches IN COLLECT(m) | 
CASE WHEN (T1 = startNode(matches) AND (matches.ft_home_score > matches.ft_away_score))
OR (T1 = endNode(matches) AND (matches.ft_away_score > matches.ft_home_score))
THEN {wins: initial.wins + 1, max_wins: CASE WHEN initial.wins + 1 > initial.max_wins THEN initial.wins + 1 ELSE initial.max_wins END}
ELSE initial
END).max_wins AS successive_wins
return T1.name AS Team, successive_wins ORDER BY successive_wins DESC

上面代码的结果是：

Team    successive_wins
"Manchester City FC"    32
"Manchester United FC"  25
"Tottenham Hotspur FC"  23
"Chelsea FC"    21
"Liverpool FC"  21
"Arsenal FC"    19
"Burnley FC"    14
"Everton FC"    13
"Newcastle United FC"   12
"Leicester City FC" 12

我认为我在REDUCE语句中做错了事，但不完全确定到底是什么：D

Answer 1

如果您有APOC程序，则可以使用集合拆分程序来提供帮助。

MATCH (T1:Team)-[m:Match]-()
with T1, m
ORDER BY m.round ASC
WITH T1, collect(NOT (T1 = startNode(m) XOR (m.ft_home_score > m.ft_away_score)) AND NOT m.ft_home_score = m.ft_away_score) as results
CALL apoc.coll.split(results, false) YIELD value
WITH T1, max(size(value)) as successive_wins
RETURN T1.name AS Team, successive_wins 
ORDER BY successive_wins DESC

关于这一点的一些注释。

我正在使用NOT ... XOR来实现XNOR，这只会使布尔逻辑稍微容易一点（两个术语均为true或两个术语均为false），尽管我们确实需要进行最后检查以确保不关系。

通过收集布尔值以获得有序的结果（如果获胜则为true，否则为false）并在false上进行拆分，我们在每一行上获得一个连续的true或连续获胜的列表，并通过获得最大的列表来获得最大数量的每队连续获胜。