确保jQAssistant中存在枚举中的方法

Question

我想确保所有枚举都有一个名为findByAttribute的静态方法。

我可以通过选择方法

MATCH (enum:Enum) - [:DECLARES] -> (method:Method)
 WHERE method.static = true
 AND method.name = "findByAttribute"
RETURN enum.name, method.name

现在，我想反转方法选择的条件。 我尝试了“ NOT EXITS但是那没有用。

Answer 1

首先，这里是您可以使用的所有运算符 ，以及如何使用它们

最简单的方法是使用气泡对逻辑进行分组。 （这可能是通读后最容易理解的）

MATCH (enum:Enum) - [:DECLARES] -> (method:Method)
 WHERE NOT (method.static = true
 AND method.name = "findByAttribute")
RETURN enum.name, method.name

下一个最好的事情是NOT (A and B) = NOT A OR NOT B

MATCH (enum:Enum) - [:DECLARES] -> (method:Method)
 WHERE NOT method.static = true
 OR NOT method.name = "findByAttribute"
RETURN enum.name, method.name

或使用不等式运算符<>而不是反转布尔值

MATCH (enum:Enum) - [:DECLARES] -> (method:Method)
 WHERE method.static <> true
 OR method.name <> "findByAttribute"
RETURN enum.name, method.name

EXISTS仅用于检查是否设置了属性，因此在这里并不适用，因为可以设置它。

---

假设您的意思是“此方法不存在的地方”，那么您就不能进行模式匹配（从return中切出method.name，因为在此版本的查询中没有逻辑方法可以包含它）

MATCH (enum:Enum) 
 WHERE NOT (enum) - [:DECLARES] -> (:Method {static:true, name:"findByAttribute"})
RETURN enum.name

Answer 2

提取上一个答案的最后一个查询并进行更正：

MATCH
  (enum:Enum:Type) 
WHERE NOT
  (enum)-[:DECLARES]->(:Method {static:true, name:"findByAttribute"})
RETURN
  enum.fqn