VBA (Excel) 中的查找函数找不到最小值

Question

我已经尝试了很多次，但我没有得到这个工作。 我想要实现的目标：在特定列 F:F 中找到最小值，然后获取该值所在的行号（或范围地址）。

注意：变量rngMinimumVariableEins必须重新格式化，因为该值非常小。

Dim rngMinimumVariableEinsWert As Range
Dim strResultValue As String
Dim rngMinimumVariableEins As Range

Set rngMinimumVariableEins = Worksheets("Berechnung").Range("F:F")
rngMinimumVariableEins.NumberFormat = "0.00000000000000000000000000"
strResultValue = Application.WorksheetFunction.Min(rngMinimumVariableEins)
Debug.Print strResultValue

Set rngMinimumVariableEinsWert = rngMinimumVariableEins.Find(strResultValue, LookIn:=xlValues, LookAt:=xlPart)
If rngMinimumVariableEinsWert Is Nothing Then
    Debug.Print "No Results"
Else
    Debug.Print rngMinimumVariableEinsWert.Row
End If

Answer 1

Excel 工作表有 15 位有效数字的浮点数限制，您永远无法在一列真实数字中可靠地找到看起来像数字的字符串。

dim minpos as variant

with Worksheets("Berechnung").range("F:F")
    minpos = application.match(application.min(.cells.value2), .cells, 0)
end with

If iserror(minpos) Then
    Debug.Print "No Results"
Else
    Debug.Print minpos
End If

Answer 2

这是找到范围RangeToSearch中最小值的行号RowOfMin的方法：

Option Explicit

Public Sub FindMinimum()
    Dim RangeToSearch As Range
    Set RangeToSearch = Worksheets("Berechnung").Columns("F")

    Dim RowOfMin As Long

    On Error Resume Next
    With Application.WorksheetFunction
        RowOfMin = .Match(.Min(RangeToSearch), RangeToSearch, 0)
    End With
    On Error GoTo 0

    If RowOfMin = 0 Then
        Debug.Print "No number values in column F"
    Else
        Debug.Print RowOfMin
    End If
End Sub

请注意，您必须避免将最小值转换为另一种数据类型（例如，通过将其写入变量），而是直接将其用于.Match ，否则您将遇到浮点问题。