Haskell - 递归堆栈溢出

Question

我试图将所有n从1加到一个非常大的数字（现在是10 ** 9），但它会给出堆栈溢出。 另外我不认为在1处停止并且在不同行中执行总和n是最有效的方式，但下面的代码是我对Haskell的全部知识。 我真的不太了解函数式编程，我想尽可能多的解释。 （我也试过把$！strict放在最后一行，这在其他地方被告知但是没有改变。如果你解释了我能做这种递归函数最有效的方法，我会很高兴的。）

main :: IO()

summ 1 = 1
summ n = 1/(n**2) + summ (n-1)

expected_value = pi*pi/6
errorPercent n = n / expected_value * 100

main = do
    putStr "%"
    print (errorPercent (summ $! (10**9)))

Answer 1

chi回答了一个问题，我认为这是主要的问题，但还有其他一些问题让我烦恼。 当你说10**9 ，你得到一个浮点数 （因为**是“分数”取幂）。 然后，您使用浮点相等来检查递归的基本情况。

summ 1 = ...

这样做的问题在于它是可能的，并且随着参数变大，可能会因为数值误差而几乎不会错过基本情况并永远下降到负值。

summ 4 =        ... summ 3
summ 3 =        ... summ 2.000001
summ 2.000001 = ... summ 1.000001 
summ 1.000001 = ... summ 0.000001  -- BASE CASE MISSED!
summ 0.000001 = ... summ (-1.000001)
summ (-1.000001) = ... summ (-2.000001)

等等。 如果你没有从10 ^9个电话中获得堆栈溢出，你肯定会无限多。

您应该在整数上定义函数，这样就没有舍入错误

summ :: Int -> Double
summ 1 = 1
summ n = 1 / (fromIntegral n ** 2) + summ (n - 1)
--            ^^^^^^^^^^^^
-- conversion necessary to go from Int to Double

main = ... print (summ (10 ^ 9))
--                      ^^^^^^
--      use integral exponentiation (^) instead of (**)

或使用更宽容的基础案例

summ :: Double -> Double
summ n | n <= 1 = 1
summ n = 1 / (n ** 2) + summ (n - 1)

在任何一种情况下，你绝对应该采取chi的建议，以累加器的方式做到这一点，你也应该明确地设置类型签名。

如果你好奇的话， 更多关于你如何在Haskell中获得堆栈溢出的问题 。

Answer 2

这里的问题是，在整个10 ^ 9递归调用结束之前，总和无法开始计算。 从本质上讲，你是在计算

1/(n**2) + ( 1/((n-1)**2) + ( 1/((n-2)**2) + ....

并且括号阻止开始求和。 相反，我们希望拥有

(( 1/(n**2) + 1/((n-1)**2) ) + 1/((n-2)**2) ) + ....

最简单的方法是使用“累加器”附加参数：

summ 1 acc = 1 + acc
summ n acc = summ (n-1) $! acc + 1/(n**2)

main = do
    putStr "%"
    print (errorPercent (summ (10^9) 0))  -- set acc to 0 at the beginning

为了提高性能，我建议在summ添加一个类型签名，例如summ :: Int -> Double -> Double 。

---

完整的程序如下。 这里运行12秒（ ghc -O2 ）。

summ :: Int -> Double -> Double
summ 1 acc = 1 + acc
summ n acc = summ (n-1) $! acc + 1 / (fromIntegral n**2)

main :: IO ()
main = do
    putStr "%"
    print (summ (10^9) 0)  -- set acc to 0 at the beginning