有序遍历树并将给定函数应用于所有节点

Question

我写了一个有序树遍历函数：

let rec inOrder (tree: BinTree<'a>) : 'a list =
    match tree with
    | Leaf -> []
    | Node(x,l,r) -> (inOrder l) @ [x] @ (inOrder r)

现在我想使用这个函数来“映射”所有音符并应用一个作为参数给出的函数。 它应该接受一个函数和一棵树，然后返回一棵树。 这是我到目前为止：

let mapInOrder f t = 
    inOrder t
    |> Map.ofList

例如，如果我给函数这个输入：

mapInOrder float (Node(1,Node(2,Leaf,Leaf),Node(3,Leaf,Leaf)));;

我想要输出：

(Node(1.0,Node(2.0,Leaf,Leaf),Node(3.0,Leaf,Leaf)))

Answer 1

要将功能映射到List使用功能List.map ：

let mapInOrder f t = 
    inOrder t
    |> List.map f

但是此函数将产生一个List作为输出。 您的示例将产生：

[ 1.0 ; 2.0 ; 3.0 ]

要产生输出，您希望mapInOrder应该遍历该树，然后将函数应用于每个元素，再生成另一棵树。

Answer 2

这是我随附的：

type BinTree<'a> =
    | Leaf 
    | Node of x :'a  * l:BinTree<'a> * r:BinTree<'a>

let rec inOrder (tree: BinTree<'a>) : 'a list =
    match tree with
    | Leaf -> []
    | Node(x,l,r) -> (inOrder l) @ [x] @ (inOrder r)

let exampleTree = (Node(1,Node(2,Leaf,Leaf),Node(3,Leaf,Leaf)));;

let mapInOrder tree mapFunc = 
    tree
        |> inOrder 
        |> List.map mapFunc

let res = mapInOrder exampleTree double
//val res : double list = [2.0; 1.0; 3.0] <-------------- result of your current try

let rec copyAndMapInOrder<'b> (tree: BinTree<'a>) mapFunc : BinTree<'b> =
    match tree with
    | Leaf -> Leaf
    | Node(x,l,r) -> Node((mapFunc x), (copyAndMapInOrder l mapFunc), (copyAndMapInOrder r mapFunc))

let res2 = copyAndMapInOrder exampleTree double
//val res2 : BinTree<double> = Node (1.0,Node (2.0,Leaf,Leaf),Node (3.0,Leaf,Leaf)) <-- expected result

这段代码只是我对@AMieres上面建议的实现。

Answer 3

添加到其他答案中的一件简单的事情。 您可以定义折叠函数并从中导出其他函数。

let rec fold  (e: 'b) (f : 'a -> 'b -> 'b -> 'b) (tree: BinTree<'a>) : 'b =
    match tree with
    | Leaf -> e
    | Node(x,l,r) -> f x (fold e f l) (fold e f r)

let inorderTree  f t = fold Leaf (fun x l r -> Node (f x, l, r)) t
let inorderList  f t  = fold [] (fun x l r -> l @ [f x] @ r) t
let inorderList' t  = inorderList id t
let inorderTree' t  = inorderTree id t