从列表中删除重复项，但在SWI-Prolog中不返回两个相同的结果？

Question

duplicate([],[]).
duplicate([A|B],[A|B1]) :- not(member(A,B)), duplicate(B,B1).
duplicate([A|B],List) :- member(A,B), duplicate(B,List).

我写这个谓词是为了从列表中删除重复项，但是当我测试它时，

?- duplicate([a,b,c,a,d,c,b,a,e,f],N).
N = [d, c, b, a, e, f] ;
N = [d, c, b, a, e, f] ;
false.

有没有办法只保留一个结果，而不是两个相同的结果？ （因此它只会返回一个列表）。

另外，不允许我使用修改回溯搜索的运算符，例如cut运算符！，否定运算符not，+或if-then-else运算符->和;

如果有人可以帮助我，将不胜感激。 ：D

Answer 1

收到多个答案的实际原因是目标member(A,As) 。 它为As重复项生成多个答案。

?-  member(a, [a,a]).
    true
;   true.

有几种出路。

memberchk/2或once/1

memberchk/2定义为

memberchk(X, Xs) :-
   once(member(X, Xs)).

这将删除其他答案。 但是，这也可能删除其他有效的解决方案。 考虑：

?-        memberchk(X, [a,b]), b = X.
false.
?- b = X, memberchk(X, [a,b]), b = X.
b = X.

因此， memberchk/2对精确的实例化很敏感，这使其成为非常脆弱的，不纯洁的谓词。

但这有一个好处：它只针对以下问题提供一个答案

?- memberchk(a, [a,a]).
true.

因此，理想的是一个既纯净又坚持第一个要素的定义。 输入

memberd/2

memberd(X, [X|_Ys]).
memberd(X, [Y|Ys]) :-
   dif(X, Y),
   memberd(X, Ys).

在此定义中，仅当列表元素不同时，递归规则才有意义。 因此，该规则将永远不适用于memberd(a, [a,a,a]) 。

您定义中的另一个问题not(member(A,B)) ，如果A和B被充分实例化，它只会按预期方式工作。 您的定义失败： duplicate([a,X],[a,b]). 尽管有一个解决方案： X = b 。

而是将其替换为non_member/2 。

另外，如果您对最有效的解决方案感兴趣，请考虑可用于SICStus和SWI的 library(reif) ，这将导致：

list_nub([], []).
list_nub([X|Xs], Ys0) :-
   if_(memberd_t(X, Xs),  Ys0 = Ys1, Ys0 = [X|Ys1]),
   list_nub(Xs, Ys1).

Answer 2

这是删除所有重复项的一种方法，不是最有效的方法，但我认为很容易理解意图。

rm_duplicates(In, Out) :-
    exclude(has_duplicate(In), In, Out).

has_duplicate(List, Case) :-
    dif(I, J),
    nth0(I, List, Case),
    nth0(J, List, Case).

如果您打算将列表放入集合中：

list_to_set(List, Set).

记录在案： list_to_set / 2