最快/最优雅的方法来遍历范围以在excel VBA中查找值

Question

美好的一天，

在我的项目中，遇到很多情况，我需要我的代码在给定范围内多次查找某个字符串，并在找到该字符串时执行许多操作。

我写了一个适合我需要的Do..Loop ，但是由于我不是最优雅的程序员（我是自学成才的），所以我想知道其他更快或更优雅的方法。

示例代码：

Set FindStr = .Sheets(c).Range("C2:C" & LRow).Find("MANUALLY", lookat:=xlWhole)
If Not FindStr is Nothing Then
    FRow = FindStr.Row
End If

Do While Not FindStr Is Nothing
    If FindStr.Offset(0,2) = "SA" Then
        FindStr.Offset(0,5) = "Confirmed"
    End If
    Set FindStr = .Sheets(c).Range("C2:C" & LRow).Find("MANUALLY", after:=FindStr, lookat:=xlWhole)

    If Not FindStr Is Nothing Then
        If FindStr.Row = FRow then Exit Do
    End If
Loop

Answer 1

如果要继续搜索，可以使用FindNext而不是重新开始新搜索。

您唯一需要知道的是，一旦完成， FindNext将在顶部继续搜索。 为了告诉您搜索再次开始，您保存了第一个匹配项的地址，如果FindNext返回您的第一个匹配项的地址，您就知道已经完成了。

变量命名的一句话： Find/FindNext返回Ranges ，并且应该给变量起一个反映该名称的名称。 FindStr表示它包含一个字符串，这不是正确的。 Range的默认属性是它的值，因此它看起来好像是一个字符串-但不是。

看一下这段代码：

Const searchStr = "MANUALLY"
With .Sheets(c).Range("C2:C" & LRow)
    Dim findRange As Range, firstHit As Range
    Set findRange = .Find(searchStr, lookat:=xlWhole)
    If Not findRange Is Nothing Then
        Set firstHit = findRange     ' Remember first hit.
        Do
            ' ... (Do your stuff here)
            Set findRange = .FindNext(findRange)
        Loop While Not findRange Is Nothing And findRange.Address <> firstHit.Address
    Else
        ' in case you didn't find anything
    End If
End With