图是序言中的树吗

Question

我正在学习 Prolog，我有这段代码可以确定图形是否是树。 如果没有循环并且边是连接的，则图是树。

我的问题是：我怎样才能得到解决方案？

例如这张图？

Graph = [ab, bc, bd, cd] 我想弄清楚它是如何工作的。

stree(Graph,Tree):-
  subset(Graph, Tree),
  tree(Tree),
  covers(Tree, Graph).

tree(Tree):-
   connected(Tree),
   not hasacycle(Tree).

connected(Graph):-
   not(node(A, Graph),node(B,Graph), 
   not path(A,B,Graph,_)).

hasacycle(Graph):-
   adjacent(Node1,Node2,Graph), 
   path(Node1,Node2,Graph,[Node1,X,Y|_]).

covers(Tree,Graph):-
  not(node(Node,Graph),
  not node(Node,Tree)).

subset([],[]).
subset([X|Set],subset):-
 subset(Set,subset).
subset([X|Set],[X|subset]):-
 subset(Set, subset).

Answer 1

直接回答你的问题

您询问了如何检查一个图是否是 Prolog 中的树，特别是对于您的示例图：

测试.pl：

node(a,graph1).
node(b,graph1).
node(c,graph1).
node(d,graph1).

edge(a,b,graph1).
edge(b,c,graph1).
edge(b,d,graph1).
edge(c,d,graph1).

adjacent(X,Y,Graph) :-
  (edge(X,Y,Graph) ; edge(Y,X,Graph)).

travel(A,B,PathSuffix,Path,Graph) :-
  adjacent(A,B,Graph),
  Path = [B|PathSuffix].

travel(A,B,PathSuffix,Path,Graph) :-
  adjacent(A,C,Graph),
  C \== B,
  \+ member(C,PathSuffix),
  travel(C,B,[C|PathSuffix],Path,Graph).

path(A,B,Path,Graph) :-
  travel(A,B,[A],ReversedPath,Graph),
  reverse(ReversedPath,Path).

connected(Graph) :-
  not((
    node(A,Graph),
    node(B,Graph),
    not(path(A,B,_,Graph))
  )).

hascycle(Graph) :-
   node(A,Graph),
   node(B,Graph),
   adjacent(A,B,Graph), 
   path(A,B,[A,_,_|_],Graph).

tree(Graph) :-
   connected(Graph),
   not(hascycle(Graph)).

$ swipl
?- [test].
?- tree(graph1).
false.

图的结构在原子node和edge中编码。

path规则基于此示例。

规则connected 、 hascycle和tree对应于程序中的规则。

注意大写标识符是变量： Graph是一个变量，而graph1是一个常量。

---

对您的代码的评论

您提供的代码存在多个问题：

它不使用 SWI Prolog 8.0.1 编译。 我不得不用not(A)替换not A的未加括号的用法。 此外，我必须将not(A,B)形式的用法替换为not((A,B)) 。 如果您的程序为您编译，请指定您使用的是哪个 Prolog 编译器/解释器。

您的代码不包含path的定义，请参阅上面链接的示例。

您的代码包含额外的规则stree ，据称检查Tree是否是Graph的生成树，以及辅助规则cover和subset 。

subset的定义完全被打破了：除了subset([],[])基本情况之外，它是不可满足的，因为作为参数传递的subset是常量，而不是变量。 我想你反而想要一个subgraph(G1,G2)规则，它检查 G1 的每个节点都是 G2 的节点，并且 G1 中的每对相邻节点在 G2 中也是相邻的。