检查每行中的列并捕获每个唯一值并分配给变量

Question

我有以下代码循环每一行并执行代码来更改值。 我还希望它为每一行捕获位于C列的处理器名称，但我不想要重复的名称。 然后，我将使用这些名称来编写我准备的自动电子邮件代码。 我不知道如何将名称捕获到每行没有重复的变量中。

Dim x as Integer
Application.ScreenUpdating = False
      NumRows = Range("A2", Range("A2").End(xlDown)).Rows.Count
      Range("A2").Select
      For x = 2 To NumRows + 1
         Range("A" & x).Validation.Delete
         If ActiveSheet.Range("T" & x).Value > 1 Then ActiveSheet.Range("G" & x).Value = "YES" ' Else
         If ActiveSheet.Range("T" & x).Value < 1 Then ActiveSheet.Range("G" & x).Value = "NO" ' Else

'HERE IS WHERE I WANT TO ADD THE CODE I NEED HELP WITH

         ActiveCell.Offset(1, 0).Select
      Next
      Application.ScreenUpdating = True

Answer 1

该集合非常易于使用。

在循环遍历单元格的过程中，您可以遍历集合并检查重复项。 然后使用布尔值设置是否存在重复，从而是否将值添加到集合中。 这是一个没有变量名称的示例结构。

[x] = var

Dim [collection] As New Collection, [cell] as Range, [range] as Range, [boolean] as Boolean, [item] as Variant

For Each [cell] In [range]
    [boolean] = False
    For Each [item] In [collection]
        If [item] = [cell].Value Then
            [boolean] = True
            Exit For
        End If
    Next [item]
    If [boolean] = False Then [collection].Add [cell].Value
Next [cell]

然后你可以再次使用for循环读取所有项目：

For Each [item] In [collection]
    Debug.Print [item]
next [item]

Answer 2

你可以尝试：

Option Explicit

Sub TEST()

    Dim LastRow1 As Long, i As Long
    Dim dict As New Scripting.Dictionary

    With ThisWorkbook.Worksheets("Sheet1")

        'Find Last row of sheet 1 column C
        LastRow1 = .Cells(.Rows.Count, "C").End(xlUp).Row

        'Start looping rows from row 2 to lastrow1
        For i = 2 To LastRow1

            'If item not exist in in dictionary
            If Not dict.Exists(.Range("C" & i).Value) Then

                'If dictionary is empty
                If dict.Count = 0 Then
                    dict.Add .Range("C" & i).Value, dict.Count
                Else
                    dict.Add .Range("C" & i).Value, dict.Count + 1
                End If

            End If

        Next i

    End With

End Sub