根据连续变量的起始/初始值设置参数

Question

任务 ：

• 我有一个变量y1其衍生物是由某些定律驱动的
  例如y1 = sin(time)
  我为此设定了起始值
  例如， y1 = 3.0
• 我有第二个变量y2
  由y2 = y1 + offset定义
• 现在，我希望这个偏移是一个Parameter （因此在模拟过程中是恒定的），并根据y1和y2起始/初始值进行评估
  喜欢offset = y2.start - y1.start

码

从概念上讲，我想实现：

model SetParametersFromInitialValues

Real y1(start = 3.0, fixed = true);
Real y2(start = 3.0, fixed = true);
parameter Real offset(fixed = false);

initial equation
  offset = y2.start - y1.start;
equation
  der(y1) = sin(time);
  y2 = y1 + offset;

end SetParametersFromInitialValues;

我认为它可以工作，因为start应该是内置类型Real的参数属性，但它不能以这种方式使用。

我还想过使用discrete而不是parameter ，但我不知道这是否会影响性能。
然而，即使在这种情况下，我也会得到一些危险的警告（因为代数循环），即“不可能象征性地检查给定的初始化系统的一致性，因为相关的方程式是代数循环的一部分。这不是支持了。“

model SetParametersFromInitialValues

Real y1(start = 3.0, fixed = true);
discrete Real offset(fixed = false);
Real y2(start = 5.0, fixed = true);

equation
  when initial() then
    offset = y2 - y1;
  end when;
  der(y1) = sin(time);
  y2 = y1 + offset;

end SetParametersFromInitialValues;

问题 ：

• 有没有办法用Parameter实现我想要的东西？ 我是否被迫使用更多“变量”变量？
• 是否需要fixed属性？ 如果y1和y2值是从其他组件fixed ，该怎么办？ 如果他们不是？

（请注意我认为它与将模型参数定义为变量不同，因为我需要根据初始值来评估参数）

Answer 1

在初始方程部分中使用它们的名称访问变量的初始值。 通过一些较小的修改，您的代码可与Dymola和OpenModlica一起使用：

model SetParametersFromInitialValues
  Real y1(start=3.0, fixed=true);
  Real y2(start=2.0, fixed=true);
  final parameter Real offset(fixed=false);
equation 
  der(y1) = sin(time);
  y2 = y1 + offset;
end SetParametersFromInitialValues;

注意，这里不需要初始方程部分，因为方程在初始化期间也是有效的。 有关详细说明，请参阅以下详细信息

有关删除的初始等式的详细信息

Modelica规范3.40在第8.6章初始化，初始方程和初始算法中写入：

初始化使用在预期操作中使用的所有方程和算法[例如模拟或线性化]。

由于我们已经在方程部分中指定了y2 = y1 + offset ，因此不能在初始方程部分再次声明该等式（ offset = y2 - y1是相同的等式，只是以另一种方式写入）。

实际上，这个例子很好地展示了Modelica如何使用方程而不是简单的赋值来描述模型。

在初始化过程中

y2 = y1 + offset

解决了

offset := y2 - y1

通过使用y1和y2起始值。

在模拟期间，使用相同的等式来计算

y2 := y1 + offset.

有关固定属性的详细信息

Modelica by Example给出了一个非常好的固定属性解释：

当start属性用作初始条件时，fixed属性会更改start属性的使用方式。 通常，start属性被视为“回退”初始条件，仅在初始方程式部分中明确指定的初始条件不足时使用。 但是，如果将fixed属性设置为true，则将start属性视为将其用作显式初始方程（即，它不再用作回退，而是将其视为严格的初始条件）。

所以不使用fixed = true我们可以重新配置上面的代码如下：

model SetParametersFromInitialValues2
  Real y1;
  Real y2;
  final parameter Real offset(fixed=false);
initial equation 
  y1 = 3;
  y2 = 1;
equation 
  der(y1) = sin(time) + 1;
  y2 = y1 + offset;
end SetParametersFromInitialValues2;

Answer 2

您可以引入用于设置起始值的参数，可能看起来不那么优雅，然后计算偏移很容易，并且它引入了从参数对话框设置起始值的可能性。

model SetParametersFromInitialValues

parameter Real y1_start = 3.0;
parameter Real y2_start = 3.1;
final parameter Real offset= y2_start - y1_start;

Real y1(start = y1_start, fixed = true);
Real y2(start = y2_start, fixed = true);

equation
  der(y1) = sin(time);
  y2 = y1 + offset;

end SetParametersFromInitialValues;