如何比较Excel VBA中的两个锯齿状数组

Question

我有两个参差不齐的数组，其中包含我需要比较的一些实体的信息。

Dim MyArray1()
Dim MyArray2()

MyArray1(0) = Array("ID1", 2)
MyArray1(1) = Array("ID2", 7)
MyArray1(2) = Array("ID3", 5)
MyArray1(3) = Array("ID4", 3)

MyArray2(0) = Array("ID1", 5)
MyArray2(1) = Array("ID2", 8)
MyArray2(2) = Array("ID3", 6)
MyArray2(3) = Array("ID4", 9)

我正在寻找比较这些数组的最佳方法，在这种情况下，我需要得到它们之间的数字差异。 所以ID1 = 3，ID2 = 1等。任何帮助将不胜感激！

Answer 1

如果两个数组总是具有相同的大小，那么可能更容易使用字典。

Excel VBA字典 - 完整指南

Sub COMPARING_VALUES()
Dim Dict1 As Object
Dim Dict2 As Object

Set Dict1 = CreateObject("Scripting.Dictionary")
Set Dict2 = CreateObject("Scripting.Dictionary")

With Dict1
    .Add "ID1", 2
    .Add "ID2", 7
    .Add "ID3", 5
    .Add "ID4", 3
End With

With Dict2
    .Add "ID1", 5
    .Add "ID2", 8
    .Add "ID3", 6
    .Add "ID4", 9
End With

Dim key As Variant
For Each key In Dict1.Keys
    Debug.Print Dict2(key) - Dict1(key)
Next key


End Sub

在这种情况下，您可以使用词典，因为您将数据与ID（即一个键）相关联，而不仅仅是它们在数组中的位置，因此可能更容易使用词典。

执行此代码将在调试器中打印这些值：

 3 
 1 
 1 
 6

希望您能够根据您的需求进行调整。

Answer 2

Sub compJaggedArrs()
Dim MyArray1(0 To 3)
Dim MyArray2(0 To 3)
Dim i As Long, j As Long

MyArray1(0) = Array("ID1", 2)
MyArray1(1) = Array("ID2", 7)
MyArray1(2) = Array("ID3", 5)
MyArray1(3) = Array("ID4", 3)

MyArray2(0) = Array("ID1", 5)
MyArray2(1) = Array("ID2", 8)
MyArray2(2) = Array("ID3", 6)
MyArray2(3) = Array("ID4", 9)

For i = 0 To UBound(MyArray1)
    For j = 0 To UBound(MyArray2)
        If MyArray1(i)(0) = MyArray2(j)(0) Then
            Debug.Print MyArray1(i)(0) & " difference is: " & abs(MyArray1(i)(1) - MyArray2(j)(1))       
        End If
    Next j
Next i

End Sub

当然，您可以用另一种方式输出差异。 只是不知道你想对结果做什么，它现在打印到调试窗口