如何在AppleScript中使用边栏？

Question

我想知道如何使用侧边栏创建一个窗口，基本上我想要的是一个侧边栏，通过单击名称可以打开一些窗口，如下面的示例，在此先感谢。

Answer 1

您正在寻找的是侧边栏/源列表 -您可以使用轮廓视图查看Apple的较早的SidebarDemo示例项目，以获取非常小的示例（甚至可能相对容易地转换为ASObjC）。

根据您最终想要做的事情，我想可以用AppleScript完成它，但是我认为您会发现应用程序越大，痛苦就越大。 AppleScript非常适合用于原型设计和控制其他应用程序，但是当事情开始变得庞大或复杂时（例如，您以前使用工作表的经验）就不那么重要了。 如果您打算做一些更认真的应用程序，那么您可能会考虑使用一种也更认真的语言。

Answer 2

好的，这是在Xcode AppleScript应用程序中设置边栏的步骤。 我只是在显示功能； 我会让美化给你玩。

首先（显然），设置GUI。 打开MainMenu.xib，然后从对象库中添加三个项目：

• 窗口左侧的表格视图（以显示侧边栏）
• 窗口右侧的自定义视图（以显示详细视图）
• 左侧对象列表中的阵列控制器。

它看起来应该像这样（为清楚起见，用红色注释表示）： 您将需要设置布局约束，以使边栏保持恒定的宽度，并将自定义视图粘贴到其侧面，但是您可以使用它。

现在，我们将设置绑定和其他一些细节。 首先，单击左侧的Array Controller对象，然后打开右侧的Utilities窗格。

• 单击“属性”检查器。
  • 确保“模式”为“类”并且“类名称”为NSMutableDictionary
  • 在“键”部分添加两个名称：“标题”和“ isHeader”（这些是我们将在词典中使用的键）
  • 取消“选择插入的对象”，因为这很烦人。

接下来，单击列表中的“表视图”，然后再次转到右侧的“实用程序”窗格。

• 单击“属性”检查器，然后将列数设置为1。
• 单击“绑定”检查器，转到“表内容”部分，然后创建两个绑定：
  • 在“ 内容”中，单击“ 绑定到”复选框，从弹出菜单中选择“ 阵列控制器 ”，并确保已安排 Controller Key。
  • 在“ 选择索引”中，进行相同的对象绑定，但对Controller Key使用selectionIndexes 。
• 单击“连接”检查器，并将其从代理出口拖到左侧的Delegate对象，以便表视图将AppDelegate脚本用作其表视图代理。

接下来，单击列表中的“表格单元格视图”，然后再次单击“实用程序”窗格。

• 单击“身份”检查器，然后将标识符设置为“ tableItem”（不带引号）。 这样，委托人就可以找到该特定视图并将其传递给表。

最后，单击左侧的Table View Cell对象（ 不是其上方的Table Cell View对象，也不是其下方的第二个Table View Cell：令人困惑），然后再次转到右侧的Utilities窗格。

• 单击“绑定”检查器，转到顶部的“值”部分，然后创建一个绑定：
  • 在“ 值”中，单击“ 绑定到”复选框，从弹出菜单中选择“ 表格单元格视图 ”，将“控制器键”留空，然后将“模型键路径”设置为objectValue.title。

运作方式是将字典列表转储到Array Controller中，Table View将拾取该字典并将一个字典作为其ObjectValue分发给每个Table Cell View，然后Table View Cells将提取数据并提出。

除了将脚本连接到脚本外，我们已经完成了GUI的工作。 现在，转到Xcode提供的AppDelegate脚本，然后将其更改为如下所示：

script AppDelegate
    property parent : class "NSObject"

    -- IBOutlets
    property theWindow : missing value
    property arrayController : missing value
    property detailView : missing value

    on applicationWillFinishLaunching_(aNotification)
        -- Insert code here to initialize your application before any files are opened
        (* set up list of headers and lines for the side bar *)
        set sidebarList to {{title:"Header 1", isHeader:true}, {title:"Line 1", isHeader:false}, {title:"Header 2", isHeader:true}, {title:"Line 2", isHeader:false}, {title:"Line 3", isHeader:false}, {title:"Header 3", isHeader:true}, {title:"Line 4", isHeader:false}}
        arrayController's addObjects:sidebarList
    end applicationWillFinishLaunching_

    on applicationShouldTerminate_(sender)
        -- Insert code here to do any housekeeping before your application quits 
        return current application's NSTerminateNow
    end applicationShouldTerminate_

    (* table view delegate emthods *)

    on tableView:tableView isGroupRow:row
        -- header rows are group rows
        set rowData to arrayController's arrangedObjects's objectAtIndex:row
        return rowData's isHeader
    end

    on tableView:tableView shouldSelectRow:row
        -- don't want to select header rows
        set rowData to arrayController's arrangedObjects's objectAtIndex:row
        return not (rowData's isHeader)
    end

    on tableView:tableView viewForTableColumn:column row:row
        -- header rows get a special look
        set aView to tableView's makeViewWithIdentifier:"tableItem" owner:me
        return aView
    end

    on tableViewSelectionDidChange:aNotification
        (* 
         This is method gets notified right after a selection is made. This is one of 
         the places where you can change the detail view to show a the correct view for 
         selected sidebar item. For demonstration purposes I'm just swapping out 
         TextField views with the name of the sidebar item. Not to sophisticated, 
         but it get the point across
         *)
        set tableView to aNotification's object
        set selectedRowIdx to (tableView's selectedRow) as integer
        set rowData to arrayController's arrangedObjects's objectAtIndex:selectedRowIdx
        set newLabel to current application's NSTextField's labelWithString:(rowData's title )
        set newLabel's translatesAutoresizingMaskIntoConstraints to false
        set detailSubviews to (detailView's subviews) as list
        if detailSubviews is not {} then
            set oldLabel to item 1 of detailSubviews
            detailView's replaceSubview:oldLabel |with|:newLabel
        else
            detailView's addSubview:newLabel
        end

        set constraintX to newLabel's centerXAnchor's constraintEqualToAnchor:(detailView's centerXAnchor)
        set constraintY to newLabel's centerYAnchor's constraintEqualToAnchor:(detailView's centerYAnchor)
        constraintX's setActive:true
        constraintY's setActive:true
    end

end script

我添加了两个属性-arrayController和detailView，它们的值均为'missing value'（表明它们是IBOutlets）-我们将链接到GUI。 我在applicationWillFinishLaunching_添加了两行以创建记录列表，并将其添加到Array Controller中，其余的是Table View调用的委托方法。

要链接GUI，请返回MainMenu.xib，单击“阵列控制器”对象，在“实用工具”窗格中打开“连接”检查器，然后将“新引用出口”拖动到Delegate对象，并将其与属性arrayController连接。 对自定义视图执行相同的操作，将其连接到属性detailView 。 你应该很好。