在多个范围内替换#Ref

Question

如果我完全忽略上下文，因为我仍在尝试学习它们，所以对编码很抱歉。

我有单元格试图从另一个工作表中的几个 Pivot 表中提取数据。 如果它无法从 pivot 表中提取任何信息，它将返回 #REF。 宏应该在几个范围内的每个单元格中搜索以搜索 #REF 并将其替换为 0。它的几个范围而不是整个工作表的原因是某些方程试图从表中添加值由于其中一些值是#REF，因此总和也最终是#REF。 我需要将这些方程式保留在那里，这样一旦#REF 被替换，它们就会得到总和。

    Dim Areas(13) As Range
    Set Areas(1) = Range("C5:Z7")
    Set Areas(2) = Range("C10:Z14")
    Set Areas(3) = Range("C27:Z27")
    Set Areas(4) = Range("C33:Z45")
    Set Areas(5) = Range("C52:Z55")
    Set Areas(6) = Range("C58:Z61")
    Set Areas(7) = Range("C63:Z66")
    Set Areas(8) = Range("C68:Z72")
    Set Areas(9) = Range("C74:Z78")
    Set Areas(10) = Range("C80:Z84")
    Set Areas(11) = Range("C86:Z90")
    Set Areas(12) = Range("C92:Z96")
    Set Areas(13) = Range("C102:Z112")

    For R = 1 To 13
        For Each cell In Areas(R)            'Error: For Each may only iterate over a collection object 
            If cell.Value = CVErr(xlErrName) Then
                .Replace What:="#REF!", Replacement:="0", LookAt:=xlPart, _
                SearchOrder:=xlByRows, MatchCase:=False, SearchFormat:=False, _
                ReplaceFormat:=False
            Else
        Next

我在我的代码之后做了一堆笔记，试图根据我在下面列出的其他 StackOverflow 问题来解决问题。 我认为他们的工作将形成一个单一的范围，但我正在与几个工作。 如果我所做的一切都没有意义，那么请忽略以下内容并帮助我重新开始。 （拜托？）如果您需要更多信息，请告诉我。

    If IsError(cell.Value) Then
'    If cell.Value = CVErr(xlErrName) Then
'        ...
'    End If
'End If

'Dim nm As Name
'    For Each nm In ActiveWorkbook.Names
'        If InStr(nm.Value, "#REF!") > 0 Then
'            nm.Delete
'    End If
    'Next nm

'    ActiveCell.Replace What:="#REF!", Replacement:="0", LookAt:=xlPart, _
'        SearchOrder:=xlByRows, MatchCase:=False, SearchFormat:=False, _
'        ReplaceFormat:=False

'With Range("B11:AP55").SpecialCells(xlCellTypeFormulas)
'    .Formula = Replace(.Formula, "#REF", "Master", , , vbTextCompare)
'End With

Answer 1

作为Find的替代方法，请考虑SpecialCells

仅删除#REF错误

Sub Demo1()
    Dim rng As Range
    Dim rErr As Range
    Dim cl As Range

    With ActiveSheet 'or specify a specific sheet
        Set rng = .Range("C5:Z7,C10:Z14,C27:Z27,C33:Z45,C52:Z55,C58:Z61,C63:Z66,C68:Z72,C74:Z78,C80:Z84,C86:Z90,C92:Z96,C102:Z112")
    End With

    On Error Resume Next
    Set rErr = rng.SpecialCells(xlCellTypeFormulas, xlErrors)
    On Error GoTo 0

    If Not rErr Is Nothing Then
        For Each cl In rErr.Cells
            If cl.Value = CVErr(xlErrRef) Then
                cl.Offset(0, 1) = 0
            End If
        Next
    End If
End Sub

要删除所有错误：

Sub Demo2()
    Dim rng As Range
    Dim rErr As Range

    With ActiveSheet 'or specify a specific sheet
        Set rng = .Range("C5:Z7,C10:Z14,C27:Z27,C33:Z45,C52:Z55,C58:Z61,C63:Z66,C68:Z72,C74:Z78,C80:Z84,C86:Z90,C92:Z96,C102:Z112")
    End With

    On Error Resume Next
    Set rErr = rng.SpecialCells(xlCellTypeFormulas, xlErrors)
    On Error GoTo 0

    If Not rErr Is Nothing Then
        rErr = 0
    End If
End Sub