`UnitRange` 和 `Array` 有什么区别？

Question

我有两个版本的代码似乎做同样的事情：

sum = 0
for x in 1:100
    sum += x
end

sum = 0
for x in collect(1:100)
    sum += x
end

两种方法之间有实际区别吗？

Answer 1

UnitRange将使用常量空间，而Array将与您正在迭代的元素数量成比例地增长。

您可以使用BenchmarkTools package 查看差异。

julia> @btime sum(1:1000000)
  0.044 ns (0 allocations: 0 bytes)
500000500000

julia> @btime sum(collect(1:1000000))
  1.123 ms (2 allocations: 7.63 MiB)
500000500000

两种方法在空间和时间性能上都存在显着差异。 UnitRange避免了在您一次不需要时分配一大块 memory 的工作。 如果可能，更喜欢使用UnitRange而不是Array 。

Answer 2

在 Julia 中， 1:100返回一个名为UnitRange的特定结构，如下所示：

julia> dump(1:100)
UnitRange{Int64}
  start: Int64 1
  stop: Int64 100

这是一个非常紧凑的结构，用于表示具有步骤 1 和任意（有限）大小的范围。 UnitRange是AbstractRange的子类型，是表示具有任意步长的范围的类型，是AbstractVector的子类型。

每当您使用getindex （或语法糖vector[index] ）时， UnitRange的实例都会动态计算它们的元素。 例如，使用@less (1:100)[3]你可以看到这个方法：

function getindex(v::UnitRange{T}, i::Integer) where {T<:OverflowSafe}
    @_inline_meta
    val = v.start + (i - 1)
    @boundscheck _in_unit_range(v, val, i) || throw_boundserror(v, i)
    val % T
end

这是通过将i - 1添加到范围的第一个元素（ start ）来返回向量的第i个元素。 一些函数使用UnitRange优化了方法，或者更普遍地使用AbstractRange 。 例如，使用@less sum(1:100)您可以看到以下内容

function sum(r::AbstractRange{<:Real})
    l = length(r)
    # note that a little care is required to avoid overflow in l*(l-1)/2
    return l * first(r) + (iseven(l) ? (step(r) * (l-1)) * (l>>1)
                                     : (step(r) * l) * ((l-1)>>1))
end

此方法使用算术级数之和的公式，该公式非常有效，因为它是在与向量大小无关的时间内进行评估的。

另一方面， collect(1:100)返回一个包含一百个元素 1、2、3、...、100 的普通Vector 。与UnitRange （或其他类型的AbstractRange ）的主要区别在于getindex(vector::Vector, i) （或vector[i] ，带有vector::Vector ）不进行任何计算，而只是访问向量的第i个元素。 Vector优于UnitRange的缺点是，一般来说，在使用它们时没有有效的方法，因为这个容器的元素是完全任意的，而UnitRange表示一组具有特殊属性（排序、恒定步长等）的数字。 ..)。

如果您比较UnitRange具有超高效实现的方法的性能，这种类型将胜出（注意使用BenchmarkTools中的宏时使用$(...)对变量进行插值）：

julia> using BenchmarkTools

julia> @btime sum($(1:1000_000))
  0.012 ns (0 allocations: 0 bytes)
500000500000

julia> @btime sum($(collect(1:1000_000)))
  229.979 μs (0 allocations: 0 bytes)
500000500000

请记住，每次使用getindex访问元素时， UnitRange都会带来动态计算元素的成本。 例如考虑这个 function：

function test(vec)
    sum = zero(eltype(vec))
    for idx in eachindex(vec)
        sum += vec[idx]
    end
    return sum
end

让我们用一个UnitRange和一个普通的Vector对其进行基准测试：

julia> @btime test($(1:1000_000))
  812.673 μs (0 allocations: 0 bytes)
500000500000

julia> @btime test($(collect(1:1000_000)))
  522.828 μs (0 allocations: 0 bytes)
500000500000

在这种情况下，调用普通数组的 function 比使用UnitRange的更快，因为它不必动态计算 100 万个元素。

当然，在这些玩具示例中，迭代vec的所有元素而不是它的索引会更明智，但在现实世界的情况下，这样的情况可能更明智。 然而，最后一个示例表明UnitRange不一定比普通数组更有效，尤其是当您需要动态计算其所有元素时。 当您可以利用可以在恒定时间内执行操作的专用方法（如sum ）时， UnitRange会更有效。

作为文件备注，请注意，如果您最初有UnitRange ，将其转换为普通Vector以获得良好性能不一定是一个好主意，特别是如果您只使用一次或很少使用它，因为转换到Vector涉及范围内所有元素的动态计算和必要 memory 的分配：

julia> @btime collect($(1:1000_000));
  422.435 μs (2 allocations: 7.63 MiB)

julia> @btime test(collect($(1:1000_000)))
  882.866 μs (2 allocations: 7.63 MiB)
500000500000