拆分字符串数组问题 vb.net

Question

我是 VB.NET 的新手，想将字符串拆分为数组。

我有一个像这样的字符串：

613,710,200,127,127,'{\"js\":{\"\":\"16\",\"43451\":\"16\",\"65815\":\"16\",\"43452\ ":\"16\",\"41147\":\"16\",\"43449\":\"16\",\"43467\":\"16\",\"1249\": \"16\",\"43462\":\"16\",\"43468\":\"48\",\"43438\":\"64\",\"43439\":\" 80\"}}','rca',95,2048000,3,1,'AABBCCDDEEFFGGHHIIJJKKLL=','xx.xx.xx.xx',NULL

我想将其拆分为“，”处的数组。

我试过了：

Dim variable() As String
Dim stext As String

stext = "mystringhere"
variable = Split(stext, ",")

我的问题是

'{\"js\":{\"\":\"16\",\"43451\":\"16\",\"65815\":\"16\",\"43452\": \"16\",\"41147\":\"16\",\"43449\":\"16\",\"43467\":\"16\",\"1249\":\" 16\",\"43462\":\"16\",\"43468\":\"48\",\"43438\":\"64\",\"43439\":\"80\ "}}',

也是分裂的。 我希望这一切都在变量（5）中。 这可能吗？

谢谢你的帮助

Answer 1

您需要的是一个 CSV 解析器，您可以在其中设置字段引号字符。 不幸的是， VB.NET附带的 TexFieldParser 没有该功能。 幸运的是，其他人也这样做 - 这里我使用了LumenWorksCsvReader ，它以 NuGet package * 的形式提供。

Option Strict On
Option Infer On

Imports System.IO
Imports LumenWorks.Framework.IO.Csv

Module Module1

    Sub Main()
        Dim s = "613,710,200,127,127,'{\""js\"":{\""\"":\""16\"",\""43451\"":\""16\"",\""65815\"":\""16\"",\""43452\"":\""16\"",\""41147\"":\""16\"",\""43449\"":\""16\"",\""43467\"":\""16\"",\""1249\"":\""16\"",\""43462\"":\""16\"",\""43468\"":\""48\"",\""43438\"":\""64\"",\""43439\"":\""80\""}}','rca',95,2048000,3,1,'AABBCCDDEEFFGGHHIIJJKKLL=','xx.xx.xx.xx',NULL"

        Using sr As New StringReader(s)
            Using csvReader = New CsvReader(sr, delimiter:=","c, quote:="'"c, escape:="\"c, hasHeaders:=False)

                Dim nFields = csvReader.FieldCount

                While csvReader.ReadNextRecord()
                    For i = 0 To nFields - 1
                        Console.WriteLine(csvReader(i))
                    Next
                End While

            End Using
        End Using

        Console.ReadLine()


    End Sub

End Module

哪个输出

613  
710  
200  
127  
127  
{"js":{"":"16","43451":"16","65815":"16","43452":"16","41147":"16","43449":"16","43467":"16","1249":"16","43462":"16","43468":"48","43438":"64","43439":"80"}}  
rca  
95  
2048000  
3  
1  
AABBCCDDEEFFGGHHIIJJKKLL=  
xx.xx.xx.xx  
NULL

请注意，双引号在文字字符串中加倍，因为这是在 VB 中输入单个双引号的方式。

如果您真的希望保留反斜杠，请删除escape:="\"c参数。

如果您正在从文件中读取，则使用适当的StreamReader而不是 StringReader。

---

使用上述方法，也许您有一个 Windows Forms 程序，您想在其中使用来自名为“C:\temp\CsvFile.txt”的文本文件中的数据填充 RichTextBox 的内容

613,710,200,127,127,'{\""js\"":{\""\"":\""16\"",\""43451\"":\""16\"",\""65815\"":\""16\"",\""43452\"":\""16\"",\""41147\"":\""16\"",\""43449\"":\""16\"",\""43467\"":\""16\"",\""1249\"":\""16\"",\""43462\"":\""16\"",\""43468\"":\""48\"",\""43438\"":\""64\"",\""43439\"":\""80\""}}','rca',95,2048000,3,1,'AABBCCDDEEFFGGHHIIJJKKLL=','xx.xx.xx.xx',NULL
614,710,200,127,127,'{\""js\"":{\""\"":\""16\"",\""43451\"":\""16\"",\""65815\"":\""16\"",\""43452\"":\""16\"",\""41147\"":\""16\"",\""43449\"":\""16\"",\""43467\"":\""16\"",\""1249\"":\""16\"",\""43462\"":\""16\"",\""43468\"":\""48\"",\""43438\"":\""64\"",\""43439\"":\""80\""}}','din',95,2048000,3,1,'AABBCCDDEEFFGGHHIIJJKKLL=','yy.yy.yy.yy',NULL
615,710,200,127,127,'{\""js\"":{\""\"":\""16\"",\""43451\"":\""16\"",\""65815\"":\""16\"",\""43452\"":\""16\"",\""41147\"":\""16\"",\""43449\"":\""16\"",\""43467\"":\""16\"",\""1249\"":\""16\"",\""43462\"":\""16\"",\""43468\"":\""48\"",\""43438\"":\""64\"",\""43439\"":\""80\""}}','jst',95,2048000,3,1,'AABBCCDDEEFFGGHHIIJJKKLL=','zz.zz.zz.zz',NULL

你可以用上面的来想出

Imports System.IO
Imports LumenWorks.Framework.IO.Csv

Public Class Form1

    Public Class Datum
        Property A As Integer
        Property B As Integer
        Property C As Integer
        Property D As Integer
        Property E As Integer
        Property JsonData As String
        Property SocketType As String
        Property F As Integer
        Property G As Integer
        Property H As Integer
        Property I As Integer
        Property Base64Data As String
        Property IpAddy As String
        Property J As String

        Public Overrides Function ToString() As String
            Return $"{A}, {SocketType}, {IpAddy}, {B} ,{C}, {D}, {E}, {F}, {G}, {H}, {I}, {JsonData}, {Base64Data}, {J}"
        End Function

    End Class

    Public Function GetData(filename As String) As List(Of Datum)
        Dim data As New List(Of Datum)

        Using sr As New StreamReader(filename)
            Using csvReader = New CsvReader(sr, hasHeaders:=False, delimiter:=","c, quote:="'"c, escape:="\"c, comment:=Nothing, trimmingOptions:=ValueTrimmingOptions.UnquotedOnly)

                Dim nFields = csvReader.FieldCount
                If nFields <> 14 Then
                    Throw New MalformedCsvException("Did not find 14 fields in the file " & filename)
                End If

                While csvReader.ReadNextRecord()
                    Dim d As New Datum()
                    d.A = Integer.Parse(csvReader(0))
                    d.B = Integer.Parse(csvReader(1))
                    d.C = Integer.Parse(csvReader(2))
                    d.D = Integer.Parse(csvReader(3))
                    d.E = Integer.Parse(csvReader(4))
                    d.JsonData = csvReader(5)
                    d.SocketType = csvReader(6)
                    d.F = Integer.Parse(csvReader(7))
                    d.G = Integer.Parse(csvReader(8))
                    d.H = Integer.Parse(csvReader(9))
                    d.I = Integer.Parse(csvReader(10))
                    d.Base64Data = csvReader(11)
                    d.IpAddy = csvReader(12)
                    d.J = csvReader(13)

                    data.Add(d)

                End While

            End Using
        End Using

        Return data

    End Function

    Private Sub Form1_Load(sender As Object, e As EventArgs) Handles MyBase.Load
        Dim srcFile = "C:\temp\CsvData.txt"
        Dim dat = GetData(srcFile)

        For Each d In dat
            RichTextBox1.AppendText(d.ToString() & vbCrLf)
        Next

    End Sub

End Class

在尝试解析数据时，可能需要对数据执行更多检查。 请注意，我为 Datum class 的 .ToString() 方法制作了 function ，并将属性以不同的顺序排列只是为了演示其用途。

---

* Tools -> NuGet Package Manager -> Manage NuGet Packages for Solution... Choose the "Browse" tab -> type in LumenWorksCsvReader -> select the one by Sébastien Lorion et al., -> tick your project name in the pane to右键-> 单击安装。

Answer 2

我是 VB.NET 的新手，想将字符串拆分为数组。 ...变量=拆分（stext，，，，）

代替

variable = Split(stext,",")

利用

variable = stext.split(",")

如果你想让你的拆分更复杂一些，你可以创建一个 char 数据数组

dim data(3) as char
data(0) = ","c
data(1) = vbcrlf
data(2) = chr(34)
data(3) = vbtab
... and so on
variable = stext.split(data)