如何使用 awk 在日志文件中仅第一次出现

Question

我有一个这样的日志文件

some text line
other text line
<a>
  <b>1</b>
  <c>2</c>
</a>
another text line
<a>
  <b>1</b>
  <c>2</c>
</a>
yet another text line

我只需要第一次出现 XML “a”：

<a>
  <b>1</b>
  <c>2</c>
</a>

我知道

awk '/<a>/,/<\/a>/' file.log

会找到所有出现，我怎样才能得到第一个？ （添加|head -n1 显然不起作用，因为它只会捕获第一行，而且我无法确定“a”有多长，因为 awk 表达式必须是通用的，因为我有不同的日志文件具有不同的“一”内容）

Answer 1

这个 awk：

awk '
match($0,/<a>/) {
    $0=substr($0,RSTART)
    flag=1
}
match($0,/<\/a/) {
    $0=substr($0,1,RSTART+RLENGTH)
    print
    exit
}
flag' file

可以处理这些 forms：

The above awk handles this:
<a><b>1</b><c>2</c></a>
and this:
<a>
  <b>1</b>
  <c>2</c>
</a>
and also <a>
  <b>1</b>
  <c>2</c>
</a> this
the end

GNU awk 的另一个：

$ gawk -v RS="</?a>" '
NR==1 { printf RT }
NR==2 { print $0 RT }
' file

Answer 2

您能否尝试以下操作（由于是在移动设备上编写的，因此无法对其进行测试，应该可以但是）。

awk -v RS="" -v FS="<a>" '
$1!=""{
  print FS $2
  next
}
{
  print FS $1
}
' Input_file

---

---

或者试试下面的解决方案，应该比上面的解决方案更简洁、更快。

awk -v RS="" '
{
  sub(/<\/a>.*/,"</a>")
  sub(/.*<a>/,"<a>")
}
1
' Input_file

Answer 3

另一个细微的变化是简单地使用一个简单的计数器变量来指示您何时处于第一个<a>...</a>块中，输出该块然后退出。 在您的情况下，使用n作为变量在第一个块中指示，例如

awk -v n=0 '$1=="</a>" {print $1; exit} $1=="<a>" {n=1}; n==1' f.xml

示例使用/输出

使用您的输入文件f.xml您将获得：

$ awk -v n=0 '$1=="</a>" {print $1; exit} $1=="<a>" {n=1}; n==1' f.xml
<a>
  <b>1</b>
  <c>2</c>
</a>

（注意： {n=1}和n==1规则依赖于默认操作（ print ）到 output 记录）

Answer 4

第一的：

$ awk '/<a>/{f=1} f; /<\/a>/{exit}' file
<a>
  <b>1</b>
  <c>2</c>
</a>

最后的：

$ tac file | awk '/<\/a>/{f=1} f; /<a>/{exit}' | tac
<a>
  <b>1</b>
  <c>2</c>
</a>

第N个：

$ awk -v n=2 '/<a>/{c++} c==n{print; if (/<\/a>/) exit}' file
<a>
  <b>1</b>
  <c>2</c>
</a>